procedure VarClearRare(var V: TVarData);
var
  LHandler: TCustomVariantType;
begin

  // let CORBA deal with its own type
  if V.VType = varAny then
    ClearAnyProc(V)

  // ok, finally is it a custom variant type?
  else if FindCustomVariantType(V.VType, LHandler) then
    LHandler.Clear(V)
  else
    VarInvalidOp;
end;

procedure VarClearDeep(var V: TVarData);
var
  LHandler: TCustomVariantType;
begin
  // quick test for the simple ones
  if (V.VType < varInt64) then
    VarResultCheck(VariantClear(V))

  else if V.VType = varString then
  begin
{$IFNDEF NEXTGEN}
    V.VType := varEmpty;
    AnsiString(V.VString) := '';
{$ELSE NEXTGEN}
    VarInvalidOp;
{$ENDIF !NEXTGEN}
  end

  // clear the pascal unicode string correctly for reference counting
  else if V.VType = varUString then
  begin
    V.VType := varEmpty;
    UnicodeString(V.VUString) := '';
  end

  // let CORBA deal with its own type
  else if V.VType = varAny then
    ClearAnyProc(V)

  // custom handle the arrays
  else if (V.VType and varArray) <> 0 then
    VarArrayClear(V)

  // ok, finally is it a custom variant type?
  else if FindCustomVariantType(V.VType, LHandler) then
  begin
    LHandler.Clear(V);
    V.VPointer := nil;
  end

  // finally let the OS attempt to deal with it
  else
  begin
    // sometimes the OS will return an error that it doesn't know what to do
    // with the given VType.  We don't know what to do either, so we'll just
    // punt here and ignore any errors and then VarInit the variant.
    VariantClear(V);
    VariantInit(V);
  end;
end;