declare
  procedure CompareRows(Select1 varchar2, Select2 varchar2)
  is
    c1 int;
    c2 int;
    n int;
    fValue1 varchar2(32000);
    fValue2 varchar2(32000);
    fColCnt1 int;
    fColCnt2 int;
    fCols1 dbms_sql.desc_tab;
    fCols2 dbms_sql.desc_tab;
  begin
    c1 := dbms_sql.open_cursor;
    c2 := dbms_sql.open_cursor;
    dbms_sql.parse(c1, Select1, dbms_sql.native);
    dbms_sql.parse(c2, Select2, dbms_sql.native);
    dbms_sql.describe_columns(c1, fColCnt1, fCols1);
    dbms_sql.describe_columns(c2, fColCnt2, fCols2);
    for i in 1..fColCnt1 loop
      dbms_sql.define_column(c1, i, fValue1, 32000);
      dbms_sql.define_column(c2, i, fValue2, 32000);
    end loop;
    n := dbms_sql.execute_and_fetch(c1, exact=>true);
    n := dbms_sql.execute_and_fetch(c2, exact=>true);
    for i in 1..fColCnt2 loop
      dbms_sql.column_value(c1, i, fValue1);
      dbms_sql.column_value(c2, i, fValue2);
      if not (fValue1 = fValue2 or fValue1 is null and fValue2 is null) then
        dbms_output.put_line('"' || fCols1(i).col_name || '": '||fValue1||' <> '||fValue2);
      end if;
    end loop;
    dbms_sql.close_cursor(c1);
    dbms_sql.close_cursor(c2);
  end;
begin
  CompareRows('select * from all_objects where object_name=''STANDARD'' and object_type=''PACKAGE''',
              'select * from all_objects where object_name=''STANDARD'' and object_type=''PACKAGE BODY''');
end ;
/

"OBJECT_ID": 648 <> 649
"OBJECT_TYPE": PACKAGE <> PACKAGE BODY
"CREATED": 05.07.04 14:21:38 <> 05.07.04 14:21:44
"LAST_DDL_TIME": 13.12.04 10:56:48 <> 05.07.04 14:21:44
"TIMESTAMP": 2001-11-19:00:00:00 <> 2004-07-05:14:21:44