Valeriuиспользуя классический MUMPS.
Мамсее некуда...   n
  s dt1="06.08.1987"
  s dt2="15.08.2014"
  s val=$$MonDay(dt1,dt2)
  w !,val
  q

/// Число месяцев и дней в периоде
MonDay(Ds,Dp) 
  n exit,dt1,dt2,mon,day,i
  s:Ds'["." Ds=$$hd(Ds)
  s:Dp'["." Dp=$$hd(Dp)
  q:Ds[" " ""
  q:Dp[" " ""
  s dt2=$$dh(Dp)
  q:$$dh(Ds)>dt2 ""
  s dt1=Ds
  s mon=0
  s exit=0
  f i=1:1 d NEXTMON q:exit
  s day=dt2-$$dh(dt1)+(mon=0)
  q mon_","_day
NEXTMON ; Следующий месяц
  n val
  s val=$$NewDate(Ds,i,1)
  i $$dh(val)>dt2 s exit=1 q
  s mon=i
  s dt1=val 
  q 

/// Новая дата через Num месяцев
NewDate(Date,Num,Type) 
  ; Date  - дата
  ; Num   - количество месяцев 
  ; Type  - 1 уменьшить на день, если дни совпадают
  ; %korr - был или нет подбор даты
  n tp,ln,ms,newms,newyear,day,dt,hr,dt1,dat
  s Num=$g(Num,1)
  s Type=$g(Type)
  k %korr
  q:'Num Date
  s:Date["," Date=+Date 
  s ln=$l(Date)
  s tp=$s(ln=10:1,ln=8:2,1:3)
  s:tp=3 Date=$$hd(Date)
  s:tp=2 Date=$$hd($$dh(Date))
  i Date[" " zt "EmptyDate"
  s ms=$p(Date,".",2)
  s newms=ms+Num
  s newyear=newms-0.5\12+$p(Date,".",3)
  s:newms<1 newyear=newyear-1
  s newms=$tr($j(newms#12,2)," ",0)
  s newyear=$tr(newyear," ",0)
  s:'newms newms=newms+12
  s day=$p(Date,".")
  s dt="01."_newms_"."_newyear
  s dt=$$dh(dt)+day-1
  d KORRDATE
  s:Type=1&'$d(%korr) dt=$$IncDay(dt,$s(-1*Num<0:-1,1:1)) 
  s dat=$$format(dt,tp)
  q dat
KORRDATE ; Подбор дня
  n hr,i
  q:dt'>0
  s hr=dt
  f i=hr:-1 s dt=$$hd(i) q:$p(dt,".",2)=newms
  s:i'=hr %korr=1
  q

/// Инкремент даты в формате +$H и DD.MM.YYYY
IncDay(Date,Inc) 
  n typ
  s:$g(Date)="" Date=+$H
  i Date[" " zt "EmptyDate"
  s Inc=$g(Inc,1)
  s typ=1
  i Date["." s Date=$$dh(Date),typ=2
  s Date=Date+Inc
  q $s(typ=1:Date,1:$$dh(Date))

/// Форматировать дату
format(Date,Type) 
  q:Type=1 Date
  i Type=2 s $e(Date,7,8)="" q Date
  q $$dh(Date)

/// $h -> Dd.Mm.WwYy 
hd(Hor) 
  q:'$g(Hor) "" 
  q $tr("Dd.Mm.WwYy","WwYy-Mm-Dd",$zd(Hor,3))

/// Dd.Mm.WwYy -> $h 
dh(Date) 
  q:'$g(Date) "" 
  q:Date'["." Date
  s Date=$tr("WwYy-Mm-Dd","Dd.Mm.WwYy",Date)
  q $zdh(Date,3)

ValeriuКода многовато конечно ...
У нас дата используется в 3-х вариантах + 1 модификация... Да и сами функции писаны сверх защищенно...

Если убрать защиту... Сократить форматы дат - будет меньше кода.
Но это писалось один раз и черти когда. А потом просто использовалось всеми и проблем небыло.

ValeriuКода многовато конечно ...
На МСМе было еще больше.
Поскольку там небыло функций перевода даты в хоролог и обратно... Все это так же вычислялось самостоятельно...

С условием явно перемудрили...
Вот более понятный вариант. s:Type=1&'$d(%korr) dt=$$IncDay(dt,$s(Num<0:1,1:-1)) 

DAiMorНе стоит писать так условия с одним & или !, нужно писать с двойным && или ||
Я сделаю плакат с твоими рекомендациями и повешу у входа, дабы все видели.

DAiMorа по теме, есть уже все готовое для поиска разницы дат, это sql функция DATEDIFF   set date1="06.08.1987"
  set date1=$zdateh($translate(date1,".","/"),4)
  set date2=$piece($horolog,",")
  write !,"years: ",$system.SQL.DATEDIFF("yy",date1,date2)
  write !,"months: ",$system.SQL.DATEDIFF("mm",date1,date2)
  write !,"weeks: ",$system.SQL.DATEDIFF("wk",date1,date2)
  write !,"days: ",$system.SQL.DATEDIFF("dd",date1,date2)
Не факт что автору нужно "всего дней" с первой даты по вторую...
А как раз все сложность именно в тех днях, которых не хватает до месяца.

ValeriuДля GT.M например.
Там есть перевод Дд.Мм.ВвГг в хоролог и обратно?

Valeriu , просто в МСМе кроме $h ничего с датами и небыло...
Была правда процедурка с проносимыми переменными... Но это вообще фигня.