BEGIN TRAN

DECLARE
    @ITEMNO VARCHAR( 24 ) -- код товара
    ,@_ITEMNO VARCHAR( 24 )-- текущая позиция
    ,@D DATETIME -- дата периода
    ,@OPENUM INT -- начальный остаток
    ,@_OPENUM INT -- расчетный остаток для след. периода
    ,@OPENCOST DECIMAL( 18 , 2 )-- начальная стоимость
    ,@_OPENCOST DECIMAL( 18 , 2 )-- расчетная стоимость для след. периода
    ,@INPUTUM INT -- поступление, кол-во
    ,@INPUTCOST DECIMAL( 18 , 2 )-- стоимость поступивщего
    ,@OUTUM INT -- выбытие, кол-во
    ,@OUTCOST DECIMAL( 18 , 2 )-- расчетная себестоимость
    ,@I INT -- номер периода

DECLARE C CURSOR FOR
SELECT TOP  100  PERCENT ITEMNO,PDATE,OH,AMOH,P,AMP,S
FROM INV01 WHERE PDATE >= :StartPeriod
ORDER BY ITEMNO,PDATE

OPEN C

FETCH NEXT FROM C INTO @ITEMNO,@D,@OPENUM,@OPENCOST,@INPUTUM,@INPUTCOST,@OUTUM
SET @_ITEMNO = @ITEMNO
SET @I =  0 
SET @_OPENUM = @OPENUM
SET @_OPENCOST = @OPENCOST

WHILE @@FETCH_STATUS =  0 
BEGIN
SET @OUTCOST =  0 
IF (@_OPENUM + @INPUTUM) >  0 
    SET @OUTCOST = (@_OPENCOST + @INPUTCOST)/(@_OPENUM + @INPUTUM)*@OUTUM

-- Обновление расчетной таблицы
IF @I >  0 
    UPDATE INV01 SET
    OH = @_OPENUM
    ,AMOH = @_OPENCOST
    ,CMS = @OUTCOST
    WHERE ITEMNO = @ITEMNO AND PDATE = @D
ELSE
    UPDATE INV01 SET CMS = @OUTCOST
    WHERE ITEMNO = @ITEMNO AND PDATE = @D
-- Расчет остатков для следующего периода
SET @_OPENUM = @_OPENUM + @INPUTUM - @OUTUM
SET @_OPENCOST = (@_OPENCOST + @INPUTCOST) - @OUTCOST


FETCH NEXT FROM C INTO @ITEMNO,@D,@OPENUM,@OPENCOST,@INPUTUM,@INPUTCOST,@OUTUM
SET @I = @I +  1 

IF @ITEMNO <> @_ITEMNO
BEGIN
        SET @_ITEMNO = @ITEMNO
        SET @I =  0 
        SET @_OPENUM = @OPENUM
        SET @_OPENCOST = @OPENCOST
END -- новая позиция

END -- все позиции обработаны

CLOSE C
DEALLOCATE C

IF @@ERROR <>  0 
ROLLBACK TRAN
ELSE
COMMIT TRAN;