Public Sub MacrosList()
    Application.Dialogs(xlDialogRun).Show
End Sub

Public Sub MacrosList2()
    Dim vbc As VBComponent
    Dim lngStart As Long
    Dim strMsg As String
    Dim strProcName As String
    
    For Each vbc In ThisWorkbook.VBProject.VBComponents
        With vbc.CodeModule
            If vbc.Type = vbext_ct_StdModule Then
                lngStart = .CountOfDeclarationLines +  1 
                
                Do Until lngStart >= .CountOfLines
                    strMsg = strMsg & .ProcOfLine(lngStart, _
                      vbext_pk_Proc) & vbCr
                    lngStart = lngStart + .ProcCountLines( _
                      .ProcOfLine(lngStart, vbext_pk_Proc), vbext_pk_Proc)
                Loop
            End If
        End With
    Next vbc
    
    MsgBox strMsg
End Sub

Public Sub GetMacroCode()
    Dim cm As CodeModule
    Dim lngStart As Long
    Dim lngCount As Long
    
    Set cm = ThisWorkbook.VBProject. _
      VBComponents("Module2").CodeModule
    
    lngStart = cm.ProcStartLine("MacrosList2", vbext_pk_Proc)
    lngCount = cm.ProcCountLines("MacrosList2", vbext_pk_Proc)
    
    MsgBox cm.Lines(lngStart, lngCount)
    
    Set cm = Nothing
End Sub