Private Sub Workbook_Open()
Dim Сервер As Workbook

' открываем Addin(1) 
   Set Сервер = Workbooks.Open(Filename:=ThisWorkbook.Path & "\AddIn1.xls", ReadOnly:=True)
' закрываем AddIn(2)
   ThisWorkbook.Close

End Sub

Sub СозданиеМеню()
' Макрос создания пользовательского меню на основе данных листа "ЛистМеню" надстройки
'   Выполяется при открытии книги.
Dim ЛистМеню As Worksheet
Dim ОбъектМеню As CommandBarPopup
Dim ОпцииМеню() As Object
Dim ОпцияПодменю As CommandBarButton
Dim Строка As Integer
Dim УровеньМеню, СледУровень, ПозицияИлиМакрос, Подпись, Разделитель, Иконка, Доступность
    
'   Расположение данных меню
    Set ЛистМеню = ThisWorkbook.Sheets("ЛистМеню")
    
'   Инициализация счетчика строк
    Строка = 2
    
'   Добавляет меню и все вложенные в него элементы
    Do Until IsEmpty(ЛистМеню.Cells(Строка, 1))
        ' Чтение данных очередной строки с листа "ЛистМеню"
        With ЛистМеню
            УровеньМеню = .Cells(Строка, 1)
            Подпись = .Cells(Строка, 2)
            ПозицияИлиМакрос = .Cells(Строка, 3)
            Разделитель = .Cells(Строка, 4)
            Иконка = .Cells(Строка, 5)
            СледУровень = .Cells(Строка + 1, 1)
            Доступность = .Cells(Строка, 6)
        End With
        
        If УровеньМеню = 1 Then
        ' Создание опции меню первого уровня
            Set ОбъектМеню = Application.CommandBars(1). _
                Controls.Add(Type:=msoControlPopup, _
                Before:=ПозицияИлиМакрос, _
                Temporary:=False)
            ОбъектМеню.Caption = Подпись
        ElseIf УровеньМеню = 2 Then
            ' Создание опции меню второго уровня
            If СледУровень = УровеньМеню + 1 Then
            ' Создание подменю
                ReDim Preserve ОпцииМеню(УровеньМеню - 1) As Object
                Set ОпцииМеню(УровеньМеню - 1) = ОбъектМеню.Controls.Add(Type:=msoControlPopup)
            Else
            ' Создание опции
                ReDim Preserve ОпцииМеню(УровеньМеню - 1) As Object
                Set ОпцииМеню(УровеньМеню - 1) = ОбъектМеню.Controls.Add(Type:=msoControlButton)
                ОпцииМеню(УровеньМеню - 1).OnAction = ПозицияИлиМакрос
                If Доступность <> "" Then ОпцииМеню(УровеньМеню - 1).Enabled = False
            End If
            ОпцииМеню(УровеньМеню - 1).Caption = Подпись
            If Иконка <> "" Then ОпцииМеню(УровеньМеню - 1).FaceId = Иконка
            If Разделитель Then ОпцииМеню(УровеньМеню - 1).BeginGroup = True
        Else
            ' Создание опций меню уровней больше второго
            If СледУровень = УровеньМеню + 1 Then
            ' Создание подменю
                ReDim Preserve ОпцииМеню(УровеньМеню - 1) As Object
                Set ОпцииМеню(УровеньМеню - 1) = ОпцииМеню(УровеньМеню - 2).Controls.Add(Type:=msoControlPopup)
            Else
            ' Создание опции
                ReDim Preserve ОпцииМеню(УровеньМеню - 1) As Object
                Set ОпцииМеню(УровеньМеню - 1) = ОпцииМеню(УровеньМеню - 2).Controls.Add(Type:=msoControlButton)
                ОпцииМеню(УровеньМеню - 1).OnAction = ПозицияИлиМакрос
                If Доступность <> "" Then ОпцииМеню(УровеньМеню - 1).Enabled = False
            End If
            ОпцииМеню(УровеньМеню - 1).Caption = Подпись
            If Иконка <> "" Then ОпцииМеню(УровеньМеню - 1).FaceId = Иконка
            If Разделитель Then ОпцииМеню(УровеньМеню - 1).BeginGroup = True
        End If
        Строка = Строка + 1
    Loop

End Sub