Привет alex2123131 ;)

Вот пример работы с sql mdsn

Option Explicit
Private Sub Command1_Click()
'The following code is used with DAO to open an ODBC database,
'process a query, and return a set of records.
'Notice that this code makes a "DSN-less" connection
Dim ws As Workspace
Dim db As Database
Dim rs As Recordset
Dim sql As String
sql = "Select * From titles"
Set ws = DBEngine.Workspaces(0)
Dim cnStr As String
cnStr = "driver={SQL Server};server=mysvr;" & _
"database=pubs;uid=myuid;pwd=mypwd"
Set db = ws.OpenDatabase(Name:="PUBS", Exclusive:=False, _
ReadOnly:=False, Connect:=cnStr)
Set rs = db.OpenRecordset(sql, dbOpenDynaset)
rs.MoveLast
MsgBox "DAO: " & Str(rs.RecordCount) & " rows returned."
rs.Close
db.Close
ws.Close
End Sub

Обрати внимание на строчку Set db = ws.OpenDatabase(Name:="PUBS", Exclusive:=False, ReadOnly:=False, Connect:=cnStr)

Возможно в этом вся загвоздка.

Для полноты пример от туда же по добавлению данных к базе. возможно тоже не будет лишним. (Aсcsess)

Sub DAOAddRecord()

Dim db As DAO.Database
Dim rst As DAO.Recordset

' Open the database
Set db = DBEngine.OpenDatabase(".\NorthWind.mdb")

' Open the Recordset
Set rst = db.OpenRecordset _
("SELECT * FROM Customers", dbOpenDynaset)

' Add a new record
rst.AddNew

' Specify the values for the fields
rst!CustomerId = "HENRY"
rst!CompanyName = "Henry's Chop House"
rst!ContactName = "Mark Henry"
rst!ContactTitle = "Sales Representative"
rst!Address = "40178 NE 8th Street"
rst!City = "Bellevue"
rst!Region = "WA"
rst!PostalCode = "98107"
rst!Country = "USA"
rst!Phone = "(425) 555-9876"
rst!Fax = "(425) 555-8908"

' Save the changes you made to the
' current record in the Recordset
rst.Update

' For this example, just print out
' CustomerId for the new record
' Position recordset on new record
rst.Bookmark = rst.LastModified
Debug.Print rst!CustomerId

' Close the recordset
rst.Close

End Sub

Ну и напоследок в mdsn есть указание на примеры поставляемые с sql, лежат в

C:\Program Files\Microsoft SQL Server\80\Tools\Devtools\Samples\Oleauto\

Все хорошего :)