Option Base  0 

' ***************************************************
' создание двумерного массива (M x N), заполнение его
' случайными целыми числами в диапазоне 0 - 1000,
' транспонирование исходного массива
'
' размерности массива вводятся в диалоге, вывод исходного
' и транспонированного массивов - в окно отладки
Sub TwoDimArray()
Dim arrBase%(), arrTrans%()
Dim s$, i%, ii%
Dim M%, N%

' ввод размерностей исходного массива
Do
    s = InputBox("Введите размерности массива M,N." _
            & vbCrLf & "Вводить через запятую.")
    If s = "" Then Exit Sub
    i = InStr( 1 , s, ",")
    If i =  0  Then
        s = "Неверно введены размерности массива." & vbCrLf _
            & "Следует вводить через запятую."
    Else
        On Error Resume Next
        M = CInt(Left(s, i -  1 )) -  1 
        If Err.Number =  0  And M >=  0  Then
            N = CInt(Mid(s, i +  1 )) -  1 
            If Err.Number =  0  And N >=  0  Then Exit Do Else s = "N."
        Else:   s = "M."
        End If
        
        Err.Clear
        On Error GoTo  0 
        s = "Неверно указана размерность " & s
    End If
    s = s & vbCrLf & "Повтроить ввод?"
    If MsgBox(s, vbExclamation + vbYesNo) <> vbYes Then Exit Sub
Loop

' реинициализация исходного массива
ReDim arrBase(M, N)

' заполнение исходного массива
Randomize (Time)
For i =  0  To M
    For ii =  0  To N
        arrBase(i, ii) = Int( 1001  * Rnd)
    Next ii
Next i

' вывод исходного массива
Call PrintTwoDimArray("Исходный массив", arrBase)

' транспонирование исходного массива
Call TwoDimArrayTranspose(arrBase, arrTrans)
Debug.Print ""

' вывод транспонированного массива
Call PrintTwoDimArray("Транспонированный массив", arrTrans)

' освобождение памяти
Erase arrBase, arrTrans
End Sub

' ***************************************************
' транспонирование двумерного массива
' параметры:
'    arrIN  - исходный массив
'    arrOUT - транспонированный массив
Sub TwoDimArrayTranspose(arrIN, arrOUT)
Dim i%, ii%

ReDim arrOUT(LBound(arrIN,  2 ) To UBound(arrIN,  2 ), _
             LBound(arrIN) To UBound(arrIN))

For i = LBound(arrIN) To UBound(arrIN)
    For ii = LBound(arrIN,  2 ) To UBound(arrIN,  2 )
        arrOUT(ii, i) = arrIN(i, ii)
    Next ii
Next i
End Sub

' ***************************************************
' вывод двумерного массива в окно отладки
' параметры:
'    sTitle - "заголовок"
'    arr - массив
Sub PrintTwoDimArray(sTitle$, arr)
Dim i%, ii%

Debug.Print sTitle
For i = LBound(arr) To UBound(arr)
    For ii = LBound(arr,  2 ) To UBound(arr,  2 )
        Debug.Print arr(i, ii); Tab;
    Next ii
    Debug.Print ""
Next i
End Sub