Public Function Sort() As Boolean
  If (m_hwndLV) Then Sort = m_ListViewSort.Sort(m_hwndLV, m_SortColumn, m_SortOrder, m_SortType)
End Function

'm_ListViewSort -модуль
Public Function Sort(ByVal hListView As Long, ByVal Column As Integer, ByVal SortOrder As eSortOrderConstants, ByVal SortType As eSortTypeConstants) As Boolean
Dim lRet As Long
  m_lColumn = CLng(Column)
  Select Case SortOrder
    Case soDefault
      m_PRECEDE = 1
      m_FOLLOW = -1
      lRet = SendMessageLong(hListView, LVM_SORTITEMSEX, hListView, AddressOf pvCompareIndex)
    Case soAscending, soDescending
      m_PRECEDE = SortOrder
      m_FOLLOW = -SortOrder
      Select Case SortType
        Case [stString]
          lRet = SendMessageLong(hListView, LVM_SORTITEMSEX, hListView, AddressOf pvCompareText)
        Case [stStringSensitive]
          lRet = SendMessageLong(hListView, LVM_SORTITEMSEX, hListView, AddressOf pvCompareTextSensitive)
        Case [stNumeric]
          lRet = SendMessageLong(hListView, LVM_SORTITEMSEX, hListView, AddressOf pvCompareValue)
        Case [stDate]
          lRet = SendMessageLong(hListView, LVM_SORTITEMSEX, hListView, AddressOf pvCompareDate)
      End Select
  End Select
  Sort = CBool(lRet)
End Function

Private Function pvCompareIndex(ByVal lParam1 As Long, ByVal lParam2 As Long, ByVal hWnd As Long) As Long
  If (lParam1 > lParam2) Then
    pvCompareIndex = m_PRECEDE
  ElseIf (lParam1 < lParam2) Then
    pvCompareIndex = m_FOLLOW
  End If
End Function

Private Function pvCompareText(ByVal lParam1 As Long, ByVal lParam2 As Long, ByVal hWnd As Long) As Long
  Dim val1 As String
  Dim val2 As String
  val1 = LCase$(pvGetItemText(hWnd, lParam1))
  val2 = LCase$(pvGetItemText(hWnd, lParam2))
  If (val1 > val2) Then
    pvCompareText = m_PRECEDE
  ElseIf (val1 < val2) Then
    pvCompareText = m_FOLLOW
  End If
End Function

Private Function pvCompareTextSensitive(ByVal lParam1 As Long, ByVal lParam2 As Long, ByVal hWnd As Long) As Long
  Dim val1 As String
  Dim val2 As String
  val1 = pvGetItemText(hWnd, lParam1)
  val2 = pvGetItemText(hWnd, lParam2)
  If (val1 > val2) Then
    pvCompareTextSensitive = m_PRECEDE
  ElseIf (val1 < val2) Then
    pvCompareTextSensitive = m_FOLLOW
  End If
End Function

Private Function pvCompareValue(ByVal lParam1 As Long, ByVal lParam2 As Long, ByVal hWnd As Long) As Long
  Dim val1 As Double
  Dim val2 As Double
  val1 = pvGetItemValue(hWnd, lParam1)
  val2 = pvGetItemValue(hWnd, lParam2)
  If (val1 > val2) Then
    pvCompareValue = m_PRECEDE
  ElseIf (val1 < val2) Then
    pvCompareValue = m_FOLLOW
  End If
End Function

Private Function pvCompareDate(ByVal lParam1 As Long, ByVal lParam2 As Long, ByVal hWnd As Long) As Long
  Dim val1 As Date
  Dim val2 As Date
  val1 = pvGetItemDate(hWnd, lParam1)
  val2 = pvGetItemDate(hWnd, lParam2)
  If (val1 > val2) Then
    pvCompareDate = m_PRECEDE
  ElseIf (val1 < val2) Then
    pvCompareDate = m_FOLLOW
  End If
End Function

Private Function pvGetItemText(ByVal hWnd As Long, ByVal lParam As Long) As String
  Dim nRet As Long
  With m_uLVI
    .mask = LVIF_TEXT
    .iSubItem = m_lColumn
    .pszText = Space(MAX_LVMSTRING)
    .cchTextMax = Len(.pszText)
  End With
  nRet = SendMessage(hWnd, LVM_GETITEMTEXT, lParam, m_uLVI)
  pvGetItemText = Left$(m_uLVI.pszText, nRet)
End Function

Private Function pvGetItemValue(ByVal hWnd As Long, ByVal lParam As Long) As Double
  Dim sText As String
  Dim nRet As Long
  With m_uLVI
    .mask = LVIF_TEXT
    .iSubItem = m_lColumn
    .pszText = Space(MAX_LVMSTRING)
    .cchTextMax = Len(.pszText)
  End With
  nRet = SendMessage(hWnd, LVM_GETITEMTEXT, lParam, m_uLVI)
  If nRet = 0 Then
    pvGetItemValue = -1
  Else
    sText = Left$(m_uLVI.pszText, nRet)
    If (IsNumeric(sText)) Then
      pvGetItemValue = CDbl(sText)
    Else
      pvGetItemValue = CDbl(Val(sText))
    End If
  End If
End Function

Private Function pvGetItemDate(ByVal hWnd As Long, ByVal lParam As Long) As Date
  Dim sText As String
  Dim nRet As Long
  With m_uLVI
    .mask = LVIF_TEXT
    .iSubItem = m_lColumn
    .pszText = Space(MAX_LVMSTRING)
    .cchTextMax = Len(.pszText)
  End With
  nRet = SendMessage(hWnd, LVM_GETITEMTEXT, lParam, m_uLVI)
  sText = Left$(m_uLVI.pszText, nRet)
  If (IsDate(sText)) Then pvGetItemDate = sText
End Function