Option Explicit

Private Declare Function FindWindowEx Lib "user32" Alias "FindWindowExA" (ByVal hWnd1 As Long, ByVal hWnd2 As Long, ByVal lpsz1 As String, ByVal lpsz2 As String) As Long
Private Declare Function FindWindow Lib "user32" Alias "FindWindowA" (ByVal lpszClass As String, ByVal lpszTitle As String) As Long
Private Declare Function SetTimer Lib "user32" (ByVal hwnd As Long, ByVal nIDEvent As Long, ByVal uElapse As Long, ByVal lpTimerFunc As Long) As Long
Private Declare Function KillTimer Lib "user32" (ByVal hwnd As Long, ByVal nIDEvent As Long) As Long
Private Declare Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
Private Declare Function GetWindowLong Lib "user32" Alias "GetWindowLongA" (ByVal hwnd As Long, ByVal nIndex As Long) As Long
Private Declare Function SetWindowLong Lib "user32" Alias "SetWindowLongA" (ByVal hwnd As Long, ByVal nIndex As Long, ByVal dwNewLong As Long) As Long

Public Enum eStyleBox
    ES_DEFAULT = &H0
    ES_UPPERCASE = &H8
    ES_NUMBER = &H2000
    EM_PASSWORD = &HCC
End Enum


Private Const GWL_STYLE = (-16)
Private Const GWL_EXSTYLE = (-20)

Private m_strTitle As String
Private m_StyleBox As eStyleBox

Public Function InputBoxEx(ByVal strPromt As String, _
                           ByVal strTitle As String, _
                           Optional ByVal strDefault As String = "", _
                           Optional ByVal StyleBox As eStyleBox = eStyleBox.ES_DEFAULT _
                           ) As String
    m_strTitle = strTitle
    m_StyleBox = StyleBox
    
    SetTimer Application.hwnd, 0&, 100&, AddressOf TimerProc
    InputBoxEx = InputBox(strPromt, strTitle, strDefault)
End Function

Private Sub TimerProc(ByVal hwnd As Long, ByVal uMsg As Long, ByVal idEvent As Long, ByVal dwTime As Long)
    Dim hEditWnd As Long
    hEditWnd = FindWindowEx(FindWindow("#32770", m_strTitle), 0&, "Edit", vbNullString)
    
    If hEditWnd > 0 Then
        Select Case m_StyleBox
            Case EM_PASSWORD
                SendMessage hEditWnd, EM_PASSWORD, 42&, 0&
            Case ES_NUMBER, ES_UPPERCASE
                SetWindowLong hEditWnd, GWL_STYLE, GetWindowLong(hEditWnd, GWL_STYLE) Or m_StyleBox
        End Select
    End If
    
    KillTimer hwnd, idEvent
End Sub