' ==============================================================
' script:     modem01.vbs 26-MAY-2012 by скукотища
' purpose:    enumerates POTS modems' status/parameters
' language:   VBScript
' parameters: no
' host:       script.exe
' ==============================================================
' http://msdn.microsoft.com/en-us/library/windows/desktop/aa394360%28v=vs.85%29.aspx
' ==============================================================
option explicit

const MAX_ConfigManagerErrorCode=&H1F&
const MAX_Availability=&H11
const NA="N/A"

dim wmi
dim mdms,mdm
dim aAvailability, aConfigManagerError
dim sep, banner

Set wmi  = getobject("winmgmts:\\.\root\cimv2")
set mdms = wmi.execquery("select * from Win32_POTSModem")

if mdms.count>0 then
  call setpdb()
  wscript.echo "modems count: "& mdms.count
  for each mdm in mdms
    wscript.echo sep
    wscript.echo "DeviceType:             "& mdm.DeviceType
    
    wscript.echo "Caption:                "& mdm.Caption
    wscript.echo "Description:            "& mdm.Description
    
    wscript.echo "AttachedTo:             "& mdm.AttachedTo
    wscript.echo "DeviceLoader:           "& mdm.DeviceLoader
    if mdm.Availability <=MAX_Availability then
    wscript.echo "Availability:           ("& tohex(mdm.Availability) &") "& aAvailability(mdm.Availability)
    else
    wscript.echo "Availability:           "& NA
    end if
    if mdm.ConfigManagerErrorCode<=MAX_ConfigManagerErrorCode then
    wscript.echo "ConfigManagerErrorCode: ("& tohex(mdm.ConfigManagerErrorCode) &") "& aConfigManagerError(mdm.ConfigManagerErrorCode)
    else
    wscript.echo "ConfigManagerErrorCode: "& NA
    end if
  next
else
  wscript.echo "modems not found"
end if
wscript.echo banner
wscript.quit


function tohex(i):tohex="0x"& hex(i):end function

sub setpdb()
  aAvailability= _
  array("WTF?..." _
  ,"Other" _
  ,"Unknown" _
  ,"Running or Full Power" _
  ,"Warning" _
  ,"In Test" _
  ,"Not Applicable" _
  ,"Power Off" _
  ,"Off Line" _
  ,"Off Duty" _
  ,"Degraded" _
  ,"Not Installed" _
  ,"Install Error" _
  ,"Power Save - Unknown"& vbcrlf & space(24) &"The device is known to be in a power save mode, but its exact status is unknown." _
  ,"Power Save - Low Power Mode"& vbcrlf & space(24) &"The device is in a power save state but still functioning, and may exhibit degraded performance." _
  ,"Power Save - Standby"& vbcrlf & space(24) &"The device is not functioning, but could be brought to full power quickly." _
  ,"Power Cycle" _
  ,"Power Save - Warning"& vbcrlf & space(24) &"The device is in a warning state, though also in a power save mode.")
  
  aConfigManagerError= array( _
  "Device is working properly." _
  ,"Device is not configured correctly." _
  ,"Windows cannot load the driver for this device." _
  ,"Driver for this device might be corrupted, or the system may be low on memory or other resources." _
  ,"Device is not working properly."& vbcrlf & space(24) &"One of its drivers or the registry might be corrupted." _
  ,"Driver for the device requires a resource that Windows cannot manage." _
  ,"Boot configuration for the device conflicts with other devices." _
  ,"Cannot filter." _
  ,"Driver loader for the device is missing." _
  ,"Device is not working properly."& vbcrlf & space(24) &"The controlling firmware is incorrectly reporting the resources for the device." _
  ,"Device cannot start." _
  ,"Device failed." _
  ,"Device cannot find enough free resources to use." _
  ,"Windows cannot verify the device's resources." _
  ,"Device cannot work properly until the computer is restarted." _
  ,"Device is not working properly due to a possible re-enumeration problem." _
  ,"Windows cannot identify all of the resources that the device uses." _
  ,"Device is requesting an unknown resource type." _
  ,"Device drivers must be reinstalled." _
  ,"Failure using the VxD loader." _
  ,"Registry might be corrupted." _
  ,"System failure."& vbcrlf & space(24) &"If changing the device driver is ineffective, see the hardware documentation."& vbcrlf & space(24) &"Windows is removing the device." _
  ,"Device is disabled." _
  ,"System failure."& vbcrlf & space(24) &"If changing the device driver is ineffective, see the hardware documentation." _
  ,"Device is not present, not working properly, or does not have all of its drivers installed." _
  ,"Windows is still setting up the device." _
  ,"Windows is still setting up the device." _
  ,"Device does not have valid log configuration." _
  ,"Device drivers are not installed." _
  ,"Device is disabled."& vbcrlf & space(24) &"The device firmware did not provide the required resources." _
  ,"Device is using an IRQ resource that another device is using." _
  ,"Device is not working properly."& vbcrlf & space(24) &"Windows cannot load the required device drivers.")
  
  sep   = vbcrlf & string(23,"=") &" "& string(55,"=")
  banner= vbcrlf &"http://msdn.microsoft.com/en-us/library/windows/desktop/aa394360%28v=vs.85%29.aspx"& vbcrlf
end sub