Private Declare Function WideCharToMultiByte Lib "kernel32" ( _
   ByVal CodePage As Long, ByVal dwFlags As Long, _
   ByVal lpWideCharStr As Long, ByVal cchWideChar As Long, _
   lpMultiByteStr As Any, ByVal cchMultiByte As Long, _
   ByVal lpDefaultChar As Long, ByVal lpUsedDefaultChar As Long) As Long
'Cyrillic Alphabet (DOS)866
'Cyrillic Alphabet (Windows)1251
'Cyrillic Alphabet (ISO)28595
'Cyrillic Alphabet (KOI8-R)20866

Public Sub Test()
 Dim SrcStr As String
 Dim bDst() As Byte
 Dim ccLen As Long
 Dim nRet As Long
 
 SrcStr = "У попа была собака" & vbCrLf & "Он её любил" & vbCrLf & _
          "Она съела кусок мяса" & vbCrLf & "Он её убил" & vbCrLf
 ccLen = Len(SrcStr)
 'Вычисляем размер буфера
 nRet = WideCharToMultiByte(866, 0, StrPtr(SrcStr), ccLen, ByVal 0&, 0, 0, 0)
 If nRet > 0 Then
    ReDim bDst(0 To nRet - 1) As Byte 'Выделяем буфер
    'Конвертируем
    nRet = WideCharToMultiByte(866, 0, StrPtr(SrcStr), ccLen, bDst(0), nRet, _
                               0, 0)
 End If
 'Записываем буфер в файл
 Dim nFile As Integer
 nFile = FreeFile
 Open "C:\Temp\Story866.txt" For Output Access Write Lock Read Write As #nFile
 Close #nFile
 Open "C:\Temp\Story866.txt" For Binary Access Write Lock Write As #nFile
 Put #nFile, , bDst
 Close #nFile
End Sub