strBufer=a.readAll 

Public Sub Test02()
    Dim strFilePath As String
   
    Dim dtmBegin As Date
    Dim dtmEnd As Date
    Dim dtmDifference As Date


    dtmBegin = Now

    strFilePath = "D:\work\LOGOUTPUT\system\tmp\tmp.txt"
    
    FileParse strFilePath

    dtmEnd = Now
    dtmDifference = dtmEnd - dtmBegin
    MsgBox "time " & Format(dtmDifference, "HH:mm:ss")
End Sub

Private Sub FileParse(ByVal strFilePath As String)
    Dim strBuffer As String

    FileRead strFilePath, strBuffer
    BufferParse strBuffer
End Sub

Private Sub FileRead(ByVal strFilePath As String, ByRef strBuffer As String)
    Dim lngFileLength As Long
    Dim lngFileHandle As Long

    lngFileHandle = FreeFile()
    Open strFilePath For Binary Access Read Shared As lngFileHandle

    lngFileLength = LOF(lngFileHandle)
    strBuffer = String(lngFileLength, 0)

    Get lngFileHandle, , strBuffer
    Close lngFileHandle
End Sub

Private Sub BufferParse(ByRef strBuffer As String)
    Dim CriteryPosition As Long        '-начальная позиция, найденного совпадения по заданному критерию
    Dim LnBeginSectionPos As Long      '-Начальная позиция секции лога
    Dim LnEndSectionPos As Long        '-Конечная позиция секции лога
    Dim lngCurrentPosition As Long     '-Текущая позиция в буфере
    Dim TmpPosition As Long            '-Промежуточная позиция в буфере при поиске начала и конца секции
    Dim strUserInfo As String          '-Переменная критерия поиска
    Dim strLineBegin As String         '-Сстроковое значение означающее начало строки
    'Dim strLineEnd As String           '-Строковое значение означающее конец строки
    Dim SectionBegin As String         '-Строковое значение означающее начало секции лога
    'Dim SectionEnd As String          '-Строковое значение означающее конец секции лога
    Dim strFound As String             '-Отобранная секция лога, подходящая по критерию поиска
    Dim strFileRezPath As String
    Dim FileHandle As Long

    strUserInfo = Me.fld_cliName.Text
    strLineBegin = vbCrLf
    'strLineEnd = vbCrLf
    SectionBegin = ">IncomingTime"
    'SectionEnd = ">OutgoingTime"
    strFileRezPath = "D:\work\LOGOUTPUT\system\tmp\tmp_rez.txt"
    FileHandle = FreeFile()
    Open strFileRezPath For Append Lock Write As FileHandle

    lngCurrentPosition = 1
    Do While lngCurrentPosition <= Len(strBuffer)
        ' ищем совпадения с критерием поиска
        CriteryPosition = InStr(lngCurrentPosition, strBuffer, strUserInfo, VbCompareMethod.vbTextCompare)
        'MsgBox CriteryPosition
        If CriteryPosition = 0 Then
            Exit Do
        End If

        ' если совпадения по критерию найдены ищем начало текущей секции по ">IncomingTime"
        TmpPosition = InStrRev(strBuffer, SectionBegin, CriteryPosition, VbCompareMethod.vbTextCompare)
        If TmpPosition = 0 Then
            Exit Do
        End If
        ' найдя начало строки, содержащей ">IncomingTime" найдем начало секции
        LnBeginSectionPos = InStrRev(strBuffer, strLineBegin, TmpPosition, VbCompareMethod.vbTextCompare)
        If LnBeginSectionPos = 0 Then
            Exit Do
        End If
        'Теперь найдем конец секции лога, искать будем опять по ">IncomingTime" но уже следующим за _
        позицией найденой по критерию поиска.
        ' line end
     
        TmpPosition = InStr(CriteryPosition, strBuffer, SectionBegin, VbCompareMethod.vbTextCompare)
        If TmpPosition = 0 Then
            Exit Do
        End If
        ' найдя начало строки, содержащей ">IncomingTime" найдем конец текущей секции _
        (оно же начало следующей секции)
        LnEndSectionPos = InStrRev(strBuffer, strLineBegin, TmpPosition, VbCompareMethod.vbTextCompare)
        If LnEndSectionPos = 0 Then
            Exit Do
        End If
        
        strFound = Mid(strBuffer, LnBeginSectionPos + Len(strLineBegin), LnEndSectionPos - LnBeginSectionPos - Len(strLineBegin))
        
        'MsgBox strFound
        
        'FileWrite strFileRezPath, strFound
        Print #FileHandle, strFound

        lngCurrentPosition = LnEndSectionPos ' + Len(strLineEnd)
    Loop
    Close FileHandle
End Sub