Option Explicit
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
' Copyright ©1996-2009 VBnet, Randy Birch, All Rights Reserved.
' Some pages may also contain other copyrights by the author.
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
' Distribution: You can freely use this code in your own
'               applications, but you may not reproduce
'               or publish this code on any web site,
'               online service, or distribute as source
'               on any media without express permission.
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
Private Const VER_PLATFORM_WIN32s =  0 
Private Const VER_PLATFORM_WIN32_WINDOWS =  1 
Private Const VER_PLATFORM_WIN32_NT =  2 

'windows-defined type OSVERSIONINFO
Private Type OSVERSIONINFO
  OSVSize         As Long         'size, in bytes, of this data structure
  dwVerMajor      As Long         'ie NT 3.51, dwVerMajor = 3; NT 4.0, dwVerMajor = 4.
  dwVerMinor      As Long         'ie NT 3.51, dwVerMinor = 51; NT 4.0, dwVerMinor= 0.
  dwBuildNumber   As Long         'NT: build number of the OS
                                  'Win9x: build number of the OS in low-order word.
                                  '       High-order word contains major & minor ver nos.
  PlatformID      As Long         'Identifies the operating system platform.
  szCSDVersion    As String *  128  'NT: string, such as "Service Pack 3"
                                  'Win9x: 'arbitrary additional information'
End Type


'my type for holding the retrieved info
Public Type RGB_WINVER
  PlatformID      As Long
  VersionName     As String
  VersionNo       As String
  ServicePack     As String
  BuildNo         As String
End Type

Declare Function GetVersionEx Lib "kernel32" _
   Alias "GetVersionExA" _
  (lpVersionInformation As OSVERSIONINFO) As Long

Public Function GetWinVersion(win As RGB_WINVER) As String

'returns a structure (RGB_WINVER)
'filled with OS information

  #If Win32 Then
  
   Dim osv As OSVERSIONINFO
   Dim pos As Integer
   Dim sVer As String
   Dim sBuild As String
   
   osv.OSVSize = Len(osv)
   
   If GetVersionEx(osv) =  1  Then
   
     'PlatformId contains a value representing the OS
      win.PlatformID = osv.PlatformID
     
      Select Case osv.PlatformID
         Case VER_PLATFORM_WIN32s:   win.VersionName = "Win32s"
         Case VER_PLATFORM_WIN32_NT: win.VersionName = "Windows NT"
         
         Select Case osv.dwVerMajor
            Case  4 :  win.VersionName = "Windows NT"
            Case  5 :
            Select Case osv.dwVerMinor
               Case  0 :  win.VersionName = "Windows 2000"
               Case  1 :  win.VersionName = "Windows XP"
               Case  2 :  win.VersionName = "Windows 2003"
            End Select
            Case  6 :
                win.VersionName = "Windows Vista"
        End Select
                  
         Case VER_PLATFORM_WIN32_WINDOWS:
         
          'The dwVerMinor bit tells if its 95 or 98.
            Select Case osv.dwVerMinor
               Case  0 :    win.VersionName = "Windows 95"
               Case  90 :   win.VersionName = "Windows ME"
               Case Else: win.VersionName = "Windows 98"
            End Select
         
      End Select
   
   
     'Get the version number
      win.VersionNo = osv.dwVerMajor & "." & osv.dwVerMinor
  
     'Get the build
      win.BuildNo = (osv.dwBuildNumber And &HFFFF&)
       
     'Any additional info. In Win9x, this can be
     '"any arbitrary string" provided by the
     'manufacturer. In NT, this is the service pack.
      pos = InStr(osv.szCSDVersion, Chr$( 0 ))
      If pos Then
         win.ServicePack = Left$(osv.szCSDVersion, pos -  1 )
      End If

   End If
   
  #Else
  
    'can only return that this does not
    'support the 32 bit call, so must be Win3x
     win.VersionName = "Windows 3.x"
  #End If
  
End Function


Public Function IsWin95() As Boolean

'returns True if running Win95

   #If Win32 Then
  
      Dim osv As OSVERSIONINFO
   
      osv.OSVSize = Len(osv)
   
      If GetVersionEx(osv) =  1  Then
   
         IsWin95 = (osv.PlatformID = VER_PLATFORM_WIN32_WINDOWS) And _
                   (osv.dwVerMajor =  4  And osv.dwVerMinor =  0 )
                            
      End If

   #End If

End Function


Public Function IsWin98() As Boolean

  'returns True if running Win98
   Dim osv As OSVERSIONINFO

   osv.OSVSize = Len(osv)

   If GetVersionEx(osv) =  1  Then
   
      IsWin98 = (osv.PlatformID = VER_PLATFORM_WIN32_WINDOWS) And _
                (osv.dwVerMajor =  4  And osv.dwVerMinor =  10 ) And _
                (osv.dwBuildNumber >=  2222 )
                
   End If

End Function


Public Function IsWinME() As Boolean

'returns True if running Windows ME

   #If Win32 Then
  
      Dim osv As OSVERSIONINFO
   
      osv.OSVSize = Len(osv)
   
      If GetVersionEx(osv) =  1  Then
   
         IsWinME = (osv.PlatformID = VER_PLATFORM_WIN32_WINDOWS) And _
                   (osv.dwVerMajor =  4  And osv.dwVerMinor =  90 )
                            
      End If

   #End If

End Function


Public Function IsWinNT4() As Boolean

'returns True if running WinNT4

   #If Win32 Then
  
      Dim osv As OSVERSIONINFO
   
      osv.OSVSize = Len(osv)
   
      If GetVersionEx(osv) =  1  Then
   
        'PlatformId contains a value representing the OS.
        'If VER_PLATFORM_WIN32_NT and dwVerMajor is 4, return true
         IsWinNT4 = (osv.PlatformID = VER_PLATFORM_WIN32_NT) And _
                    (osv.dwVerMajor =  4 )
      End If

   #End If

End Function



Public Function IsWin2000() As Boolean

'returns True if running Windows 2000 (NT5)

   #If Win32 Then
  
      Dim osv As OSVERSIONINFO
   
      osv.OSVSize = Len(osv)
   
      If GetVersionEx(osv) =  1  Then
         IsWin2000 = (osv.PlatformID = VER_PLATFORM_WIN32_NT) And _
                     (osv.dwVerMajor =  5  And osv.dwVerMinor =  0 )
      End If

   #End If

End Function


Public Function IsWinXP() As Boolean

'returns True if running WinXP (NT5.1)

   #If Win32 Then
  
      Dim osv As OSVERSIONINFO
   
      osv.OSVSize = Len(osv)
   
      If GetVersionEx(osv) =  1  Then

         IsWinXP = (osv.PlatformID = VER_PLATFORM_WIN32_NT) And _
                   (osv.dwVerMajor =  5  And osv.dwVerMinor =  1 )
      End If

   #End If

End Function
Public Function IsWin2003() As Boolean

'returns True if running Win2003 (NT5.2)

   #If Win32 Then
  
      Dim osv As OSVERSIONINFO
   
      osv.OSVSize = Len(osv)
   
      If GetVersionEx(osv) =  1  Then

         IsWin2003 = (osv.PlatformID = VER_PLATFORM_WIN32_NT) And _
                   (osv.dwVerMajor =  5  And osv.dwVerMinor =  2 )
      End If

   #End If

End Function
Public Function IsWinVista() As Boolean

'returns True if running WinVista or Win2008 (NT6.0)

   #If Win32 Then
  
      Dim osv As OSVERSIONINFO
   
      osv.OSVSize = Len(osv)
   
      If GetVersionEx(osv) =  1  Then

         IsWinVista = (osv.PlatformID = VER_PLATFORM_WIN32_NT) And _
                   (osv.dwVerMajor =  6  And osv.dwVerMinor =  0 )
      End If

   #End If

End Function


Public Function GetWinVer() As String

'returns a string representing the version,
'ie "95", "98", "NT4", "WinXP"
   Dim osv As OSVERSIONINFO
   Dim r As Long
   Dim pos As Integer
   Dim sVer As String
   Dim sBuild As String
   
   osv.OSVSize = Len(osv)
   
   If GetVersionEx(osv) =  1  Then
   
     'PlatformId contains a value representing the OS
      Select Case osv.PlatformID
         Case VER_PLATFORM_WIN32s: GetWinVer = "32s"
         Case VER_PLATFORM_WIN32_NT:
                   
           'dwVerMajor = NT version.
           'dwVerMinor = minor version
            Select Case osv.dwVerMajor
               Case  3 :
               
                  Select Case osv.dwVerMinor
                     Case  0 :  GetWinVer = "NT3"
                     Case  1 :  GetWinVer = "NT3.1"
                     Case  5 :  GetWinVer = "NT3.5"
                     Case  51 : GetWinVer = "NT3.51"
                     Case  52 : GetWinVer = "NT3.52"
                  End Select
            
               Case  4 : GetWinVer = "NT 4"
               Case  5 :
               
                  Select Case osv.dwVerMinor
                     Case  0 :  GetWinVer = "Win2000"
                     Case  1 :  GetWinVer = "WinXP"
                     Case  2 :  GetWinVer = "Win2003"
                  End Select
               Case  6 :
                    GetWinVer = "WinVista"
            End Select
         
         Case VER_PLATFORM_WIN32_WINDOWS:
         
           'dwVerMinor bit tells if its 95 or 98.
            Select Case osv.dwVerMinor
               Case  0 :    GetWinVer = "95"
               Case  90 :   GetWinVer = "ME"
               Case Else: GetWinVer = "98"
            End Select
         
      End Select
         
   End If

End Function
'http://vbnet.mvps.org/index.html?code/system/getversionex.htm

Option Explicit

'http://www.freevbcode.com/ShowCode.asp?ID=9043
Private Declare Function GetProcAddress Lib "kernel32" _
    (ByVal hModule As Long, _
    ByVal lpProcName As String) As Long
    
Private Declare Function GetModuleHandle Lib "kernel32" _
    Alias "GetModuleHandleA" _
    (ByVal lpModuleName As String) As Long
    
Private Declare Function GetCurrentProcess Lib "kernel32" _
    () As Long

Private Declare Function IsWow64Process Lib "kernel32" _
    (ByVal hProc As Long, _
    bWow64Process As Boolean) As Long
Private Declare Function GetSystemWow64Directory Lib "Kernel32.dll" _
Alias "GetSystemWow64DirectoryA" (ByVal lpBuffer As String, ByVal uSize As Long) As Long

Public Function Is64bit() As Boolean
    Dim handle As Long, bolFunc As Boolean

    ' Assume initially that this is not a Wow64 process
    bolFunc = False

    ' Now check to see if IsWow64Process function exists
    handle = GetProcAddress(GetModuleHandle("kernel32"), _
                   "IsWow64Process")

    If handle >  0  Then ' IsWow64Process function exists
        ' Now use the function to determine if
        ' we are running under Wow64
        IsWow64Process GetCurrentProcess(), bolFunc
    End If

    Is64bit = bolFunc

End Function

Public Function GetSystemWow64Dir() As String
Dim evar As String
Dim elen As Long
    evar = String( 256 , " ")
    elen = GetSystemWow64Directory(evar, Len(evar))
    If elen =  0  Then
        'ERROR_CALL_NOT_IMPLEMENTED= 120 (0x78) ???
        GetSystemWow64Dir = ""
    Else
        evar = Left(evar, InStr(evar, Chr( 0 )) -  1 )
        GetSystemWow64Dir = CorrectDir(evar)
    End If
End Function