Option Explicit

Private Declare Function GlobalAlloc Lib  "kernel32"  ( _
  ByVal wFlags As Long, _
  ByVal dwBytes As Long) As Long

Private Declare Function GlobalLock Lib  "kernel32"  ( _
  ByVal hMem As Long) As Long

Private Declare Function GlobalUnlock Lib  "kernel32"  ( _
  ByVal hMem As Long) As Long

Private Declare Function CreateStreamOnHGlobal Lib  "ole32"  ( _
   ByVal hGlobal As Long, _
   ByVal fDeleteOnRelease As Long, _
   ppstm As IStream) As Long

Private Declare Function GetHGlobalFromStream Lib  "ole32"  ( _
  ByVal pstm As IStream, _
  phglobal As Long) As Long

Private Declare Function GlobalSize Lib  "kernel32"  ( _
  ByVal hMem As Long) As Long

Const PictureID = &H746C&
Const S_OK =  0 

' Global Memory Flags
Const GMEM_MOVEABLE = &H2
Const GMEM_ZEROINIT = &H40

Const GHND = (GMEM_MOVEABLE Or GMEM_ZEROINIT)

Private Type PictureHeader
   Magic As Long
   Size As Long
End Type

Public Function Array2Picture(aBytes() As Byte) As StdPicture
Dim oIPS As IPersistStream
Dim oStream As IStream, hGlobal As Long, lPtr As Long
Dim lSize As Long, Hdr As PictureHeader
Dim lRes As Long

   ' Create a new empty
   ' picture object
   Set Array2Picture = New StdPicture
   
   ' Get the IPersistStream interface
   Set oIPS = Array2Picture
   
   ' Calculate the array size
   lSize = UBound(aBytes) - LBound(aBytes) + 1
   
   ' Allocate global memory
   hGlobal = GlobalAlloc(GHND, lSize + Len(Hdr))
   
   If hGlobal Then
   
      ' Get a pointer to the memory
      lPtr = GlobalLock(hGlobal)
      
      ' Initialize the header
      Hdr.Magic = PictureID
      Hdr.Size = lSize
      
      ' Write the header
      MoveMemory ByVal lPtr, Hdr, Len(Hdr)
      
      ' Copy the byte array to
      ' the global memory
      MoveMemory ByVal lPtr + Len(Hdr), aBytes(0), lSize
      
      ' Release the pointer
      GlobalUnlock hGlobal
      
      ' Create a IStream object
      ' with the global memory
      lRes = CreateStreamOnHGlobal(hGlobal, True, oStream)
   
      If lRes = S_OK Then
   
         ' Load the picture
         ' from the stream
         oIPS.Load oStream
               
      End If
      
      ' Release the IStream
      ' object
      Set oStream = Nothing
   
   End If

End Function

Public Sub Picture2Array(ByVal oObj As StdPicture, aBytes() As Byte)
Dim oIPS As IPersistStream
Dim oStream As IStream, hGlobal As Long, lPtr As Long
Dim lSize As Long, Hdr As PictureHeader
Dim lRes As Long

   ' Get the IPersistStream interface
   Set oIPS = oObj
   
   ' Create a IStream object
   ' on global memory
   lRes = CreateStreamOnHGlobal(0, True, oStream)
   
   If lRes = S_OK Then
   
      ' Save the picture in the stream
      oIPS.Save oStream, True
      
      ' Get the global memory handle
      ' from the stream
      If GetHGlobalFromStream(oStream, hGlobal) = S_OK Then
      
         ' Get the memory size
         lSize = GlobalSize(hGlobal)
         
         ' Get a pointer to the memory
         lPtr = GlobalLock(hGlobal)
         
         If lPtr Then
         
            lSize = lSize - Len(Hdr)
            
            ' Redim the array
            ReDim aBytes(0 To lSize - 1)
                                             
         
            ' Copy the data to the array
            MoveMemory aBytes( 0 ), ByVal lPtr + Len(Hdr), lSize
         
         End If
         
         ' Release the pointer
         GlobalUnlock hGlobal
         
      End If
      
      ' Release the IStream
      ' object
      Set oStream = Nothing
   
   End If

End Sub

Dim d() As Byte
Dim p As AdoDB.Parameter
Dim cm As AdoDB.Command

Picture2Array(imgUserPhoto.Picture, d())

Set p = cm.CreateParameter( "UserPhoto" , adVarBinary, adParamInput)
p.Size = UBound(d()) - LBound(d()) +  1 
p.AppendChunk (d())
cm.Parameters.Append p

  With rs
    If Not IsNull(.Fields( "UserPhoto" )) Then
      Set imgUserPhoto.Picture = Array2Picture(.Fields( "UserPhoto" ).GetChunk(.Fields( "UserPhoto" ).ActualSize))
    End If
  End With