'Интерфейсный класс IMyFunc
Option Explicit

Public Function Invoke(ParamArray Args() As Variant) As Variant

End Function

'Вспомогательный модуль
Option Explicit

Public Sub PrintArgs(FuncName As String, ParamArray Args() As Variant)
 Dim i As Long
 Debug.Print FuncName,
 If Not IsMissing(Args( 0 )) Then
    For i = LBound(Args( 0 )) To UBound(Args( 0 ))
       Debug.Print Args( 0 )(i),
    Next i
 End If
 Debug.Print
End Sub

'Класс MyFunc1
Option Explicit

Implements IMyFunc

Private Function IMyFunc_Invoke(ParamArray Args() As Variant) As Variant
 PrintArgs "MyFunc1", Args()
End Function

'Класс MyFunc2
Option Explicit

Implements IMyFunc

Private Function IMyFunc_Invoke(ParamArray Args() As Variant) As Variant
 PrintArgs "MyFunc2", Args()
End Function

'Использование вышепреведённых классов в модуле формы
Option Explicit

Private m_MyFuncs As VBA.Collection

Private Function MyFunc(FuncName As String) As IMyFunc
 Set MyFunc = m_MyFuncs(FuncName)
End Function

Private Sub Command1_Click()
 'Создаём и заполняем список своих функций
 Set m_MyFuncs = New VBA.Collection
 m_MyFuncs.Add New MyFunc1, "MyFunc1"
 m_MyFuncs.Add New MyFunc2, "MyFunc2"
 
 'Вызываем функции по имени
 MyFunc("MyFunc1").Invoke  1 ,  2 ,  3 
 MyFunc("MyFunc2").Invoke  4 , "xyz"
End Sub