1. Зачем у вас вот это?

With UserForm2.ListBox1
...
End With

2. Вы передаете количество Worksheets в переменную i, а переменной k_name присваиваете имена Sheets, а совсем не Worksheets.

3. Вы квалифицируете i = ActiveWorkbook.Worksheets.Count, а в тоже время не квалифицируете Sheets(k).Name. т.е., в одном случае вам важно, что ActiveWorkbook, а в другом уже почему-то нет.

4. Вы не декларируете ваши преременные.

5. У меня пустая строка не появляется при использовании вашего кода, значит проблема не в нем, хоть он и неказист.

6. Вы вводите слишком много переменных, когда можно обойтись только одной, причем цикл много чего лишнего делает.

7. Вот пример кода, который делает тоже самое, что и ваш:

Private Sub CommandButton2_Click()
Dim objWSht As Worksheet

For Each objWSht In ActiveWorkbook.Worksheets
If objWSht.Name <> "Upravlenie zaprosami" Then
UserForm2.ListBox1.AddItem objWSht.Name
End If
Next objWSht

UserForm2.Show
End Sub

8. Вернее будет посадить заполнение лист бокса в код инициализации формы, а последнюю лишь показывать, а то ваша кнопочка CommandButton2 лезет во внутренние дела вашей формы, что нехорошо. Я подразумеваю, что CommandButton2 сидит не на форме UserForm2, а то зачем последнюю вы явно указывали бы.

Успехов

vladconn

Касательно второго вопроса: да, существует, и не один. Например, использование SQL запросов и ADO. Примеров - море.

Ну, например так:

1. В кнопке листа:

Private Sub CommandButton1_Click()
UserForm1.FileName = "C:\Temp\MyFile.txt"
UserForm1.Show
End Sub

2. В форме:

Option Explicit
Private mstrFileName As String

Public Property Get FileName() As String
FileName = mstrFileName
End Property

Public Property Let FileName(ByVal pstrNewValue As String)
mstrFileName = pstrNewValue
End Property

Private Sub UserForm_Activate()
Me.Caption = "File name " & Me.FileName
End Sub

Успехов

vladconn