Option Explicit

Const m_iColumnsCount As Integer =  15 
Const m_iRowsCount As Integer =  30000 

Dim m_sMdbPath As String, m_sConnectionString As String

Public Sub Main()
    
    Debug.Print vbCrLf & "--- Columns = " & m_iColumnsCount & ", Rows = " & m_iRowsCount
    
    If Not CreateTestMDB Then Exit Sub
    ADODB_FillTable
    ADODB_ScanTable True
    ADODB_ScanTable False
    
    If Not CreateTestMDB Then Exit Sub
    DAO_FillTable
    DAO_ScanTable True
    DAO_ScanTable False
End Sub

Private Sub DAO_ScanTable(bSnapshot As Boolean)
    Dim db As DAO.Database, r As DAO.Recordset, ii As Long
    Dim tt As Single
    
    Set db = DAO.DBEngine.OpenDatabase(m_sMdbPath)
    
    tt = Timer
    
    Set r = db.OpenRecordset("SELECT * FROM Test", IIf(bSnapshot, dbOpenSnapshot, dbOpenDynaset))
    Do Until r.EOF
        ii = ii + r( 0 )
        r.MoveNext
    Loop

    Debug.Print "DAO:   ScanTable (" & IIf(bSnapshot, "Snapshot", "Dynaset") & " Cursor) " & Format$(Timer - tt, "#,##0.000")
End Sub

Private Sub ADODB_ScanTable(bClient As Boolean)
    Dim r As New ADODB.Recordset, cn As New ADODB.Connection, ii As Long
    Dim tt As Single
    
    Set cn = New ADODB.Connection
    cn.CursorLocation = IIf(bClient, adUseClient, adUseServer)
    cn.Open m_sConnectionString
    
    tt = Timer
    
    r.Open "SELECT * FROM Test", cn, adOpenStatic, adLockOptimistic
    Do Until r.EOF
        ii = ii + r( 0 )
        r.MoveNext
    Loop
    Debug.Print "ADODB: ScanTable (" & IIf(bClient, "Client", "Server") & " Cursor) " & Format$(Timer - tt, "#,##0.000")
End Sub

Private Sub DAO_FillTable()
    Dim db As DAO.Database, r As DAO.Recordset, i As Long, k As Integer
    Dim tt As Single
    
    Set db = DAO.DBEngine.OpenDatabase(m_sMdbPath)
    
    tt = Timer
    
    Set r = db.OpenRecordset("SELECT * FROM Test", dbOpenDynaset)
    
    DBEngine.BeginTrans
    For i =  1  To m_iRowsCount
        r.AddNew
        For k =  0  To m_iColumnsCount -  1 
            Select Case k Mod  3 
                Case  0 ,  1 : r(k) = i
                Case  2 : r(k) = i & " тестовая строчка " & k
            End Select
        Next k
        r.Update
    Next i
    DBEngine.CommitTrans

    Debug.Print "DAO:     DAO_FillTable           " & Format$(Timer - tt, "#,##0.000")
End Sub

Private Sub ADODB_FillTable()
    Dim cn As New ADODB.Connection, r As New ADODB.Recordset, i As Long, k As Integer
    Dim tt As Single
    
    Set cn = New ADODB.Connection
    cn.CursorLocation = adUseClient
    cn.Open m_sConnectionString
    
    tt = Timer
    
    cn.BeginTrans
    r.Open "SELECT * FROM Test", cn, adOpenStatic, adLockBatchOptimistic
    For i =  1  To m_iRowsCount
        r.AddNew
        For k =  0  To m_iColumnsCount -  1 
            Select Case k Mod  3 
                Case  0 ,  1 : r(k) = i
                Case  2 : r(k) = i & " тестовая строчка " & k
            End Select
        Next k
        r.Update
    Next i
    r.UpdateBatch
    cn.CommitTrans

    Debug.Print "ADODB: ADODB_FillTable           " & Format$(Timer - tt, "#,##0.000")
End Sub

Private Function CreateTestMDB() As Boolean
    Dim s As String, cat As New ADOX.Catalog, t As ADOX.Table, c As ADOX.Column, i As Long, j As Long
    
    m_sMdbPath = App.Path & "\Text.mdb"
    On Error Resume Next
    Kill m_sMdbPath
    On Error GoTo  0 
    
    On Error GoTo Err_
    Set cat = New ADOX.Catalog
    m_sConnectionString = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=""" & m_sMdbPath & """"
    cat.Create m_sConnectionString

    Set t = New ADOX.Table
    t.Name = "Test"
    For i =  1  To m_iColumnsCount
        Select Case i Mod  3 
            Case  1 : t.Columns.Append "F" & i, adInteger
            Case  2 : t.Columns.Append "F" & i, adDouble
            Case  0 : t.Columns.Append "F" & i, adVarWChar,  25 
        End Select
    Next i
    cat.Tables.Append t
    cat.Tables.Refresh
    CreateTestMDB = True
    Exit Function

Err_:
    MsgBox Err.Description, vbCritical
End Function