Public Sub CreateAccessDatabaseWithAdox()
    Dim cat As ADOX.Catalog
    Dim tbl As ADOX.Table
    Dim strDbName As String
    
    strDbName = "D:\1\db10.mdb"
    
    Set cat = New ADOX.Catalog
    Set tbl = New ADOX.Table
    
    cat.Create _
      "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & strDbName
    
    With tbl
        .Name = "Table1"
        Set .ParentCatalog = cat
        .Columns.Append "ID", adInteger
        .Columns("ID").Properties("AutoIncrement") = True
        .Columns.Append "TextField", adVarWChar,  255 
        .Columns.Append "DateField", adDate
        .Columns.Append "MemoField", adLongVarWChar
        .Columns.Append "OleField", adLongVarBinary
    End With

    cat.Tables.Append tbl

    Set tbl = Nothing
    Set cat = Nothing
End Sub

Public Sub AddDataWithAdo()
    Dim cnn As ADODB.Connection
    Dim strDbName As String
    Dim strSQL As String
    
    strDbName = "D:\1\db10.mdb"
    
    strSQL = "INSERT INTO Table1 ( TextField, DateField, MemoField ) VALUES (" _
      & "'Text', #10/27/2006#, 'Large Text')"
    
    Set cnn = New ADODB.Connection
    
    cnn.Open "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & strDbName _
      & ";User Id=admin;Password=;"

    cnn.Execute strSQL
    
    cnn.Close
    Set cnn = Nothing
End Sub