Private Type FILETIME
    intLow As Long
    intHigh As Long
End Type

Private Declare Function RegOpenKeyEx Lib "advapi32.dll" _
  Alias "RegOpenKeyExA" ( _
  ByVal hKey As Long, _
  ByVal lpSubKey As String, _
  ByVal ulOptions As Long, _
  ByVal samDesired As Long, _
  phkResult As Long) As Long

Private Declare Function RegEnumKeyEx Lib "advapi32.dll" _
  Alias "RegEnumKeyExA" ( _
  ByVal hKey As Long, _
  ByVal dwIndex As Long, _
  ByVal lpName As String, _
  lpcbName As Long, _
  ByVal lpReserved As Long, _
  ByVal lpClass As String, _
  lpcbClass As Long, _
  lpftLastWriteTime As FILETIME) As Long

Private Declare Function RegCloseKey Lib "advapi32.dll" ( _
  ByVal hKey As Long) As Long

Public Const HKEY_CLASSES_ROOT = &H80000000
Public Const HKEY_CURRENT_USER = &H80000001
Public Const HKEY_LOCAL_MACHINE = &H80000002
Public Const HKEY_USERS = &H80000003

Private Const cSuccess =  0 &

Private Const SYNCHRONIZE = &H100000
Private Const STANDARD_RIGHTS_READ = &H20000
Private Const KEY_QUERY_VALUE = &H1
Private Const KEY_ENUMERATE_SUB_KEYS = &H8
Private Const KEY_NOTIFY = &H10
Private Const KEY_READ = ((STANDARD_RIGHTS_READ Or _
  KEY_QUERY_VALUE Or _
  KEY_ENUMERATE_SUB_KEYS Or _
  KEY_NOTIFY) And _
  (Not SYNCHRONIZE))

Public Sub ListSubKeys( _
  hKeyRoot As Long, _
  strSubKey As String)
    Dim hSubKey As Long
    Dim cEnum As Long
    Dim hKey As Long
    Dim lngResult As Long
    Dim strNameBuff As String
    Dim cbNameBuff As Long
    Dim strClassBuff As String
    Dim cbClassBuff As Long
    Dim typFileTime As FILETIME
    
    lngResult = RegOpenKeyEx(hKeyRoot, strSubKey, _
       0 &, KEY_READ, hSubKey)
    
    If lngResult = cSuccess Then
        Do
            strNameBuff = Space$( 255 )
            cbNameBuff = Len(strNameBuff)
            strClassBuff = Space$( 255 )
            cbClassBuff = Len(strClassBuff)
            
            lngResult = RegEnumKeyEx(hSubKey, cEnum, _
              strNameBuff, cbNameBuff,  0 &, _
              strClassBuff, cbClassBuff, typFileTime)
              
            If lngResult = cSuccess Then
                Debug.Print Left(strNameBuff, cbNameBuff)
            End If
            
            cEnum = cEnum +  1 
        Loop Until lngResult <>  0 
        
        lngResult = RegCloseKey(hSubKey)
    End If
End Sub

ListSubKeys HKEY_CURRENT_USER, "Software\VB and VBA Program Settings"