Option Explicit

Public Function UpdateApplication() As Boolean
Const UpdatePath As String = "\\Сервер такой-то\Папка такая-то\"

Dim CurAppFile As String
Dim CurVersion As String
Dim NewVersion As String
Dim FullPath As String

Dim fso As FileSystemObject
Dim curfso As FileSystemObject

Set fso = New FileSystemObject

'Узнать версию запущенного приложения
CurVersion = App.Major & "." & App.Minor & ".0." & App.Revision

'Если файл приложения существует на сервере, то
CurAppFile = App.EXEName & ".exe"
FullPath = fso.BuildPath(UpdatePath, CurAppFile)
If fso.FileExists(FullPath) Then
    
    'Узнать версию файла на сервере
    NewVersion = fso.GetFileVersion(FullPath)
    
    'Если версия файла более новая, то
    If NewVersion > CurVersion Then
         
        'Переименуем запущенный файл
        Set curfso = New FileSystemObject
        If curfso.FileExists(App.Path & "\" & App.EXEName & ".bak") Then
            curfso.DeleteFile (App.Path & "\" & App.EXEName & ".bak")
        End If
        curfso.MoveFile App.Path & "\" & CurAppFile, App.Path & "\" & App.EXEName & ".bak"
        
        'Копируем с сервера
        fso.CopyFile FullPath, App.Path & "\" & CurAppFile, True
        
        'Запускаем новый файл
        Shell App.Path & "\" & CurAppFile, vbNormalFocus
        
        'Выход из программы
        Set curfso = Nothing
        UpdateApplication = True
        
    Else
 
        UpdateApplication = False

    End If
Else

    UpdateApplication = False

End If

Set fso = Nothing

End Function

Private Sub Command1_Click()
 If UpdateApplication() Then
    Form1.Hide
    Unload Form1
 End If
End Sub