' Необходимые объявления
Private Const CONNECT_UPDATE_PROFILE = &H1

Private Const RESOURCE_GLOBALNET = &H2
Private Const RESOURCETYPE_DISK = &H1
Private Const RESOURCEDISPLAYTYPE_SHARE = &H3
Private Const RESOURCEUSAGE_CONNECTABLE = &H1

Private Type NETRESOURCE
   dwScope       As Long
   dwType        As Long
   dwDisplayType As Long
   dwUsage       As Long
   lpLocalName   As String
   lpRemoteName  As String
   lpComment     As String
   lpProvider    As String
End Type

Private Declare Function WNetAddConnection2 Lib "mpr" _
    Alias "WNetAddConnection2A" _
   (lpNetResource As NETRESOURCE, _
    ByVal lpPassWord As String, _
    ByVal lpUserName As String, _
    ByVal dwFlags As Long) As Long

' Функция оболочка
Private Function ConnectThisNetworkDrive(sServer As String, _
                                         sDrv As String, _
                                         sUser As String, _
                                         sPassword As String) As Long

   Dim NETR As NETRESOURCE
   Dim errInfo As Long
   
   With NETR
      .dwScope = RESOURCE_GLOBALNET
      .dwType = RESOURCETYPE_DISK
      .dwDisplayType = RESOURCEDISPLAYTYPE_SHARE
      .dwUsage = RESOURCEUSAGE_CONNECTABLE
      .lpRemoteName = sServer
      .lpLocalName = sDrv
   End With
   
   errInfo = WNetAddConnection2(NETR, _
                                sPassword, _
                                sUser, _
                                CONNECT_UPDATE_PROFILE)

   ConnectThisNetworkDrive = errInfo

End Function

' Затем где-нибудь вызываем, например в Form_Load() и смотрим код ошибки. Если 0, то все ОК. Если нет то нужно копаться дальше.
MsgBox ConnectThisNetworkDrive("\\server\share", "H:", "user_name", "user_password")