Public Enum XBorderWeight
    xDefault = - 1 
    xNone = - 4142 
    xHairline =  1 
    xMedium = - 4138 
    xThick =  4 
    xThin =  2 
End Enum
Public Enum XBorderPosition
    xEdgeLeft =  7 
    xEdgeTop =  8 
    xEdgeBottom =  9 
    xEdgeRight =  10 
    xInsideVertical =  11 
    xInsideHorizontal =  12 
End Enum

Public Sub Bord(ByVal rng As Excel.Range, _
                Optional ByVal linStyle As Excel.XlLineStyle = xlContinuous, _
                Optional ByVal el As XBorderWeight = xDefault, _
                Optional ByVal et As XBorderWeight = xDefault, _
                Optional ByVal eb As XBorderWeight = xDefault, _
                Optional ByVal er As XBorderWeight = xDefault, _
                Optional ByVal iv As XBorderWeight = xDefault, _
                Optional ByVal ih As XBorderWeight = xDefault)

    Dim vTmpArea As Excel.Range
On Error GoTo ErrH
    
    If Not rng Is Nothing Then
        With rng
            For Each vTmpArea In .Areas
                With vTmpArea
                    If el <> xDefault Then
                        With .Borders(xEdgeLeft)
                            If el = xNone Then
                                .LineStyle = xlNone
                            Else
                                .LineStyle = linStyle
                                .Weight = el
                                .ColorIndex = xlAutomatic
                            End If
                        End With
                    End If
                    If et <> xDefault Then
                        With .Borders(xEdgeTop)
                            If et = xNone Then
                                .LineStyle = xlNone
                            Else
                                .LineStyle = linStyle
                                .Weight = et
                                .ColorIndex = xlAutomatic
                            End If
                        End With
                    End If
                    If eb <> xDefault Then
                        With .Borders(xEdgeBottom)
                            If eb = xNone Then
                                .LineStyle = xlNone
                            Else
                                .LineStyle = linStyle
                                .Weight = eb
                                .ColorIndex = xlAutomatic
                            End If
                        End With
                    End If
                    If er <> xDefault Then
                        With .Borders(xEdgeRight)
                            If er = xNone Then
                                .LineStyle = xlNone
                            Else
                                .LineStyle = linStyle
                                .Weight = er
                                .ColorIndex = xlAutomatic
                            End If
                        End With
                    End If
                    If iv <> xDefault Then
                        If .Columns.Count >  1  Then
                            With .Borders(xInsideVertical)
                                If iv = xNone Then
                                    .LineStyle = xlNone
                                Else
                                    .LineStyle = linStyle
                                    .Weight = iv
                                    .ColorIndex = xlAutomatic
                                End If
                            End With
                        End If
                    End If
                    If ih <> xDefault Then
                        If .Rows.Count >  1  Then
                            With .Borders(xInsideHorizontal)
                                If ih = xNone Then
                                    .LineStyle = xlNone
                                Else
                                    .LineStyle = linStyle
                                    .Weight = ih
                                    .ColorIndex = xlAutomatic
                                End If
                            End With
                        End If
                    End If
                End With
            Next vTmpArea
        End With
    End If
Exit Sub
ErrH:
    Err.Raise Err.Number, "Bord", Err.Description
End Sub

Sub SomeSub()
    Dim rng As Excel.Range
On Error GoTo ErrH
    Set rng = ActiveSheet.Range("A1:B20,D10:G24")
    Bord rng, xlContinuous, xMedium, xMedium, xMedium, xMedium, xThin, xHairline
Exit Sub
ErrH:
    MsgBox Err.Description, vbCritical, Err.Source
End Sub