Option Explicit
'----------------------------------------------'
'Модуль "ЭтаКнига"                             '
'(в программном коде - ThisWorkbook)           '
'Если надстройка объёмная по коду, этот модуль '
'оформляется как интерфейс -                   '
'аналог класса, содержащего только методы.     '
'Реализация методов переносится в модули.      '
'----------------------------------------------'
Private SummProp As CommandBarButton  'пункт меню "Сумма прописью"
Private Const PropMnuName As String = "Пропись"
Private Const SumPMnuName As String = "Сумма прописью"
Private Const CntPMnuName As String = "К-во прописью"

Private Sub MakeAddIn()
'Эти операции можно делать и вручную,
'однако лень - двигатель прогресса.
'
'Перед преобразованием книги в Add-In
'дайте ей (надстройке) имя и понятный комментарий.
'В рабочей книге (там, где юзер видит Excel)
'щёлкните Файл -->Свойства-->Документ и заполните поля:
 
'"Название" - то, что увидит юзер в списке Add-Ins;
' "Заметки"  - то, что увидит юзер в рамке
'с наименованием Add-In, поместив курсор на наименование.
'
'Поместите книгу с отлаживаемым кодом
'в папку Application.Path &  "\Library" 
'и однократно выполните этот макрос из IDE:
    With ThisWorkbook
        .IsAddin = True     'Скрывает все рабочие листы.
        .SaveAs .Path &  "\"  & Left(.Name, Len(.Name) -  1 ) &  "a" 
    End With
End Sub

Private Sub MakeSimpleWorkbook()
'Рабочие листы Add-In скрыты. Для их отображения
'(там целесообразно размещать шаблоны, справочники и пр.)
'откройте надстройку, Alt-F11 и выполните этот макрос:
    With ThisWorkbook
        .IsAddin = False
        .SaveAs .Path & "\" & Left(.Name, Len(.Name) - 1) & "s"
        Dim sh As Worksheet
        For Each sh In .Worksheets
            sh.Visible = xlSheetVisible
        Next sh
    End With
End Sub
Private Sub Workbook_AddinInstall()
'Occurs when the workbook is installed as an add-in
'Т.е, когда пользователь взводит чек-бокс
'напротив строки с наименованием надстройки
'в сиске надстроек, п. меню "Сервис-->Надстройки".
    Application.ScreenUpdating = False
'Встраивание меню. (В данном случае - контекстно-зависимого):
    CreateInWordsMenu
End Sub

Private Sub Workbook_AddinUninstall()
'Occurs when any add-in workbook is uninstalled
'Пользователь может быть уведомлён, что имеющиеся
'пункты (контекстно-зависимого)меню более недоступны:
    DelInWordsMenu
End Sub

Sub CreateInWordsMenu()     'контекстно-зависимое.
Dim p As CommandBar         'панели инструментов
Dim t As CommandBarControl  'пункты меню в этих панелях
For Each p In Application.CommandBars           'перебираем все панели инструментов
    If InStr(1, p.Name, "Cell") > 0 Then        'и ищем панель  "Ячейка" :
        For Each t In p.Controls                'если там есть панель "Пропись",
            If t.Caption = PropMnuName Then Exit Sub   'то и её пункты уже встроены.
        Next t                                  'панель "Пропись"не найдена,
        With p.Controls                         'поэтому добавляем её и её пункты:
             Set SummProp = .Add(msoControlButton)
             With SummProp
                  .Caption = SumPMnuName
                  .TooltipText =  "Сумма прописью содержимого активной ячейки" 
                  .OnAction =  "SumProp" 
                  .Visible = True
             End With
             Set CntPProp = .Add(msoControlButton)
             With CntPProp
                  .Caption = CntPMnuName
                  .TooltipText =  "К-во прописью содержимого активной ячейки" 
                  .OnAction =  "CountProp" 
                  .Visible = True
             End With
         End With
         MsgBox  "Можно выводить суммы прописью"  & vbCrLf & _
                 "под суммой-числом в ячейке с курсором" , _
                vbInformation + vbOKOnly,  "Add-In 'Пропись'" 
         Exit Sub           'мавр может уходить...
    End If
Next p
End Sub

Public Sub DelInWordsMenu()
Dim p As CommandBar, t As CommandBarControl
For Each p In Application.CommandBars
    If InStr(1, p.Name, "Cell") > 0 Then
       For Each t In p.Controls
            If t.Caption = SumPMnuName Or _
               t.Caption = CntPMnuName Then
                MsgBox "Пункт меню ' " & t.Caption & " ' удалён.", _
                vbInformation + vbOKOnly, "Add-in 'Пропись'"
                t.Delete
            End If
       Next t
    End If
Next p
End Sub

Sub SumProp(ByRef R As Range)
'............
End Sub

Sub CountProp(ByRef R As Range)
'............
End Sub