Принцып тот же что и здесь

Public Function WriteRecord(ByVal CN As ADODB.Connection, _
ByVal Table As String, _
ByVal Fields As Variant, _
ByVal FieldsValue As Variant, _
ByRef ErrText As String) As Boolean

' функция добавления новой строки в таблицу
' CN - открытое подключение к БД
' Table - имя таблицы в которую добавляем запись
' Fields - массив наименований столбцов
' FieldsValue - массив значений столбцов
' В случае если среди вставляемых значений есть файл,
' то значение столбца должно содержать путь.
' При возникновении ошибки функция возвращает false, a в ErrText текст ошибки

On Error GoTo errLabel

ErrText = ""

Dim sql As String
Dim st As ADODB.Stream
Dim rs As ADODB.Recordset


' построить SQL-запрос и открыть набор записей
sql = "SELECT * FROM " & Table

Set rs = New ADODB.Recordset
Set st = New ADODB.Stream

st.Type = adTypeBinary
st.Open

rs.Open sql, CN, adOpenDynamic, adLockOptimistic
rs.AddNew

Dim i As Long
For i = LBound(Fields) To UBound(Fields)
' проверить тип поля
If rs.Fields(Fields(i)).Type = adBinary Or rs.Fields(Fields(i)).Type = adLongVarBinary Or rs.Fields(Fields(i)).Type = adVarBinary Then
st.LoadFromFile (FieldsValue(i))
rs.Fields(Fields(i)).Value = st.Read
Else
rs.Fields(Fields(i)).Value = FieldsValue(i)
End If
Next i

rs.Update

GoTo MyExit '***************************************************
errLabel:

ErrText = "Ошибка №" & Err.Number & vbCrLf & Err.Description

MyExit:
On Error Resume Next

If rs.State = adStateOpen Then rs.Close
Set rs = Nothing

If st.State = adStateOpen Then st.Close
Set st = Nothing

WriteRecord = IIf(ErrText = "", True, False)
End Function

мдя... sql-запрос у big-duke поставлен болле экономично по отношению к ресурсам...
автор big-duke писал:SELECT TOP 1 * FROM Media
поэтому в моей функции, конечно же, лучше использовать такой же запрос.

2 Boyler
для того чтобы пользоваться моим примером, нужно сначала открыть подключение к твоей базе данных. Т.е.:
public cn as adodb.connection
cn.connectionstring="Provider=Microsoft.Jet.OLEDB.4.0;" & _
Data Source=C:\m.mdb;"
cn.open

потом открываем набор записей. Т.е. показываем из какой таблицы и что выбирать автор писал:sql = "SELECT * FROM " & Table и какое подключение при ентом использовать автор писал:rs.Open sql, CN , adOpenDynamic, adLockOptimistic Второй и третий параметр здесь показывают, что рекордсет будет динамический с блокировкой записи только на время её изменения. Так как наша цель добавить новую запись, то вызываем метод rs.AddNew и простовляем значения всех полей для новой записи. Нас интересует именно то место, где вставляется файл. Т.е.
автор писал:st.LoadFromFile (FieldsValue(i))
rs.Fields(Fields(i)).Value = st.Read тоесть файл сначала загружается в объект ADODB.Stream с помощью метода LoadFromFile (ПутьКФайлу) и уже потом записывается в одну из ячеек новой записи rs.Fields(Fields(i)).Value = st.Read (метод Read позволяет считать данные из объекта Stream)