Option Compare Database
Option Explicit

Public Function ArabToRim(number As Long) As String
'autor:mailto:pas_sword@tut.by
    Dim Ary()
    Dim Num As Long
    Dim str As String
    Dim res As String
    Dim Ind As Long

    Ary = Array(1000, "M", 900, "CM", 500, "D", 400, "CD", _
                100, "C", 90, "XC", 50, "L", 40, "XL", _
                10, "X", 9, "IX", 5, "V", 4, "IV", 1, "I")

    While number > 0
        For Ind = 0 To UBound(Ary) - 1 Step 2
            Num = Ary(Ind)
            str = Ary(Ind + 1)
            While Num <= number
                res = res & str
                number = number - Num
            Wend
        Next Ind
    Wend

    ArabToRim = res
End Function

Public Function RimToArab(number As String) As Long
'autor:mailto:pas_sword@tut.by
    Dim Ary()
    Dim Num As Long
    Dim str As String
    Dim res As Long
    Dim Ind As Long

    Ary = Array( 1000 , "M",  900 , "CM",  500 , "D",  400 , "CD", _
                 100 , "C",  90 , "XC",  50 , "L",  40 , "XL", _
                 10 , "X",  9 , "IX",  5 , "V",  4 , "IV",  1 , "I")

    While Len(number) >  0 
        For Ind =  0  To UBound(Ary) -  1  Step  2 
            Num = Ary(Ind)
            str = Ary(Ind +  1 )
            While str = Left$(number, Len(str))
                res = res + Num
                number = Right$(number, Len(number) - Len(str))
            Wend
        Next Ind
    Wend

    RimToArab = res
End Function