а может слать не игре нажатия а экранной клавиатуре а она уж пошлет игре

я не понял из постов получилось ли куда-то послать сообщения например в нотепад (блокнот)
есть api SendInput с его помощью можно послать и клавиатурное и мышиное сообщение
если не получилось послать экранной клавиатуре сообщение то это странно мне кажется должно сообщение от мыши посылаться
надо сделать так
SetCursorPos установить мышь в нужную точку экрана
SendInput с параметром mouse down
подождать (а может это и не нужно ждать пробовать надо и так и так) пока ждете кнопка на экранной клавиатуре должна быть нажата если сообщение дошло
SendInput с параметром mouse up

Естественнно в хелпе надо почитать какие и как передать параметры для SetCursorPos SendInput
А на каком языке написано значения не имеет
Объявите Public Declare Function ... и тд и пользуйтесь из бейсика

вот такой последовательностью я открывал меню в нотепаде
если получилось на нотепаде пробовать на экранной клавиатуре

вот сделал то что написал проверил на нотепаде
пока прога ждет 2 секунды при запуске переключаюсь в нотепад
приходит нажатие как надо
надо только проверить что курсор попал в букву
у меня win 7 экранная клавиатура называется osk.exe
после того как заработало на нотепаде надо проверять на игре
в топике с с++ написано что directx как-то не так работает поэтому не знаю будет ли работать но не думаю что есть разница нажимать экранную клавиатуру мышью или с помощью сообщений

Attribute VB_Name = "InputEventGeneratorM"
Option Explicit


Public Const errCanNotPerformRequestedOperation As Long = 17
Public Const INPUT_MOUSE As Long = 0
Public Const MOUSEEVENTF_LEFTDOWN As Long = 2
Public Const MOUSEEVENTF_LEFTUP As Long = 4
Public Const InputItemSize As Long = 28


Public Type MouseInputT
InputType As Long
X As Long
Y As Long
MouseData As Long
Flag As Long
TimeData As Long
Extra As Long
End Type

Public Declare Sub SleepWinApi Lib "kernel32" Alias "Sleep" (ByVal lngInterval As Long)
Public Declare Function SetCursorPosWinApi Lib "user32" Alias "SetCursorPos" (ByVal lngX As Long, ByVal lngY As Long) As Long
Public Declare Function SendInputWinApi Lib "user32" Alias "SendInput" (ByVal lngInputCount As Long, ByVal lngInputList As Long, ByVal lngInputItemSize As Long) As Long


Public Sub Test01()
Dim stcMouseInput As MouseInputT
Dim lngX As Long
Dim lngY As Long
Dim lngResultBool As Long
Dim lngResultDword As Long
Dim lngErrorDword As Long

lngX = 200
lngY = 110

SleepWinApi 2 * 1000

lngResultBool = SetCursorPosWinApi(lngX, lngY)
If lngResultBool = 0 Then
lngErrorDword = Err.LastDllError
Err.Raise errCanNotPerformRequestedOperation
End If

SleepWinApi 2 * 1000

stcMouseInput.InputType = INPUT_MOUSE
stcMouseInput.X = lngX
stcMouseInput.Y = lngY
stcMouseInput.MouseData = 0
stcMouseInput.Flag = MOUSEEVENTF_LEFTDOWN
stcMouseInput.TimeData = 0
stcMouseInput.Extra = 0

lngResultDword = SendInputWinApi(1, VarPtr(stcMouseInput), InputItemSize)
If lngResultDword <> 1 Then
lngErrorDword = Err.LastDllError
Err.Raise errCanNotPerformRequestedOperation
End If

SleepWinApi 400

stcMouseInput.InputType = INPUT_MOUSE
stcMouseInput.X = lngX
stcMouseInput.Y = lngY
stcMouseInput.MouseData = 0
stcMouseInput.Flag = MOUSEEVENTF_LEFTUP
stcMouseInput.TimeData = 0
stcMouseInput.Extra = 0

lngResultDword = SendInputWinApi(1, VarPtr(stcMouseInput), InputItemSize)
If lngResultDword <> 1 Then
lngErrorDword = Err.LastDllError
Err.Raise errCanNotPerformRequestedOperation
End If

SleepWinApi 2 * 1000
End Sub

когда нажимаем кнопки на экранной клавиатуре игра их воспринимает?
если приведенный код не работает то что вылетает с ошибкой какая прога?

те экранная клавиатура здесь не помощник я читая посты понял что экранная клавиатура работает тогда зачем ее вообще было упоминать
в ссылке на с++ сказано что даже directx ввод поймет генерацию SendInput сейчас попробую сделать то что там сказано

автор ЭК работает, если программно посылать через неё имитацию клавиш в блокнот или ручками в игру
Не понял. так что же надо чтобы эклава посылала в игру. клавиши клавиатуры нажимать чтоли?
вот сделал как написано в с++ только не знаю как быть с флагом KEYEVENTF_UNICODE надо его попробовать оба варианта
в нотепад шлет "1"

еще меня смущает фраза "моя прога вылетает с ошибкой"
Test02 ни при каких условиях не должна вылетать с ошибкой а если вылетают то их генерит
сторока Err.Raise errCanNotPerformRequestedOperation
а значит надо остановиться в отладчике и посмотреть код ошибки lngErrorDword = Err.LastDllError и узнать причину ошибки api функции

Attribute VB_Name = "InputEventGeneratorM"
Option Explicit


Public Const errCanNotPerformRequestedOperation As Long = 17
Public Const INPUT_MOUSE As Long = 0
Public Const INPUT_KEYBOARD As Long = 1
Public Const MOUSEEVENTF_LEFTDOWN As Long = 2
Public Const MOUSEEVENTF_LEFTUP As Long = 4
Public Const KEYEVENTF_DOWN As Long = 0
Public Const KEYEVENTF_KEYUP As Long = 2
Public Const KEYEVENTF_UNICODE As Long = 4
Public Const KEYEVENTF_SCANCODE As Long = 8
Public Const MAPVK_VK_TO_VSC As Long = 0
Public Const InputItemSize As Long = 28


Public Type KeyboardInputT
InputType As Long
VirtualKey As Integer
ScanKey As Integer
Flag As Long
TimeData As Long
Extra As Long
End Type

Public Type MouseInputT
InputType As Long
X As Long
Y As Long
MouseData As Long
Flag As Long
TimeData As Long
Extra As Long
End Type

Public Declare Sub SleepWinApi Lib "kernel32" Alias "Sleep" (ByVal lngInterval As Long)
Public Declare Function SetCursorPosWinApi Lib "user32" Alias "SetCursorPos" (ByVal lngX As Long, ByVal lngY As Long) As Long
Public Declare Function SendInputWinApi Lib "user32" Alias "SendInput" (ByVal lngInputCount As Long, ByVal lngInputList As Long, ByVal lngInputItemSize As Long) As Long
Public Declare Function MapVirtualKeyWinApi Lib "user32" Alias "MapVirtualKeyW" (ByVal lngCode As Long, ByVal lngFlag As Long) As Long


Public Sub Test01()
Dim stcMouseInput As MouseInputT
Dim lngX As Long
Dim lngY As Long
Dim lngResultBool As Long
Dim lngResultDword As Long
Dim lngErrorDword As Long

lngX = 200
lngY = 110

SleepWinApi 2 * 1000

lngResultBool = SetCursorPosWinApi(lngX, lngY)
If lngResultBool = 0 Then
lngErrorDword = Err.LastDllError
Err.Raise errCanNotPerformRequestedOperation
End If

SleepWinApi 2 * 1000

stcMouseInput.InputType = INPUT_MOUSE
stcMouseInput.X = lngX
stcMouseInput.Y = lngY
stcMouseInput.MouseData = 0
stcMouseInput.Flag = MOUSEEVENTF_LEFTDOWN
stcMouseInput.TimeData = 0
stcMouseInput.Extra = 0

lngResultDword = SendInputWinApi(1, VarPtr(stcMouseInput), InputItemSize)
If lngResultDword <> 1 Then
lngErrorDword = Err.LastDllError
Err.Raise errCanNotPerformRequestedOperation
End If

SleepWinApi 400

stcMouseInput.InputType = INPUT_MOUSE
stcMouseInput.X = lngX
stcMouseInput.Y = lngY
stcMouseInput.MouseData = 0
stcMouseInput.Flag = MOUSEEVENTF_LEFTUP
stcMouseInput.TimeData = 0
stcMouseInput.Extra = 0

lngResultDword = SendInputWinApi(1, VarPtr(stcMouseInput), InputItemSize)
If lngResultDword <> 1 Then
lngErrorDword = Err.LastDllError
Err.Raise errCanNotPerformRequestedOperation
End If

SleepWinApi 2 * 1000
End Sub

Public Sub Test02()
Dim stcKeyboardInput As KeyboardInputT
Dim lngScanKey As Long
Dim lngVirtualKey As Long
Dim lngResultBool As Long
Dim lngResultDword As Long
Dim lngErrorDword As Long


lngScanKey = MapVirtualKeyWinApi(Asc("1"), MAPVK_VK_TO_VSC)
lngVirtualKey = 0

SleepWinApi 2 * 1000

stcKeyboardInput.InputType = INPUT_KEYBOARD
stcKeyboardInput.VirtualKey = lngVirtualKey
stcKeyboardInput.ScanKey = lngScanKey
stcKeyboardInput.Flag = KEYEVENTF_DOWN Or KEYEVENTF_SCANCODE Or KEYEVENTF_UNICODE
stcKeyboardInput.TimeData = 0
stcKeyboardInput.Extra = 0

lngResultDword = SendInputWinApi(1, VarPtr(stcKeyboardInput), InputItemSize)
If lngResultDword <> 1 Then
lngErrorDword = Err.LastDllError
Err.Raise errCanNotPerformRequestedOperation
End If

SleepWinApi 400

stcKeyboardInput.InputType = INPUT_KEYBOARD
stcKeyboardInput.VirtualKey = lngVirtualKey
stcKeyboardInput.ScanKey = lngScanKey
stcKeyboardInput.Flag = KEYEVENTF_KEYUP Or KEYEVENTF_SCANCODE Or KEYEVENTF_UNICODE
stcKeyboardInput.TimeData = 0
stcKeyboardInput.Extra = 0

lngResultDword = SendInputWinApi(1, VarPtr(stcKeyboardInput), InputItemSize)
If lngResultDword <> 1 Then
lngErrorDword = Err.LastDllError
Err.Raise errCanNotPerformRequestedOperation
End If

SleepWinApi 2 * 1000
End Sub

если я правильно понял то
1 вожу мышкой и нажимаю мышкой по эклаве - посылка в игру не работает
2 посылаю нажатия мышки в эклаву - посылка в игру не работает
3 test02 падает тогда где и какой код ошибки