oService = GetObject("winmgmts:\\.\root\cimv2")
oCollection = oService.ExecQuery("SELECT * FROM Win32_VideoController")
 
CREATE CURSOR cs (ramsize I, bpp I, hres I, vres I,;
    rrate I, vcname C(100), vmdescription C(100))
 
FOR EACH oItem IN oCollection
    WITH oItem
        INSERT INTO cs VALUES (;
            NVL(.adapterram, 0),;
            NVL(.currentbitsperpixel, 0),;
            NVL(.currenthorizontalresolution, 0),;
            NVL(.currentverticalresolution, 0),;
            NVL(.currentrefreshrate, 0),;
            NVL(.name, ""),;
            NVL(.videomodedescription, "");
        )
    ENDWITH
NEXT
 
GO TOP
BROWSE NORMAL NOWAIT
 
* * *
oService = GetObject("winmgmts:\\.\root\cimv2")
oCollection = oService.ExecQuery("SELECT * FROM Win32_DesktopMonitor")
 
CREATE CURSOR csDesktopMonitor (availability I, deviceid C(30), monitorstatus C(20),;
    DisplayType I, IsLocked I, monitorcaption C(50),;
    MonitorManufacturer C(30), PNPDeviceID C(50),;
    screenwidth I, screenheight I)
 
FOR EACH oItem IN oCollection
    WITH oItem
        INSERT INTO csDesktopMonitor VALUES (;
            NVL(.availability, 0),;
            NVL(.deviceid, ""),;
            NVL(.Status, ""),;
            NVL(.displaytype, 0),;
            NVL(.islocked, 0),;
            NVL(.caption, ""),;
            NVL(.MonitorManufacturer, ""),;
            NVL(.PNPDeviceID, ""),;
            NVL(.screenwidth, 0),;
            NVL(.screenheight, 0);
        )
    ENDWITH
NEXT
 
SELECT csDesktopMonitor
GO TOP
BROWSE NORMAL NOWAIT