Public colTextBox As New Collection 'Для хранения ссылок на классы-оболочки

Private Sub Form_Load()
    Dim xControl As Control
    Dim tbWrapper As TextBoxWrapper
    
    For Each xControl In Me.Controls
        Set tbWrapper = New TextBoxWrapper 'Создаём оболочку для текстового поля
        
        tbWrapper.Init xControl, "TextBoxAll_Change", "TextBoxAll_Click" 'Передаём поле и имена процедур
        colTextBox.Add tbWrapper 'Добавляем в коллекцию
        
        Set tbWrapper = Nothing
    Next
End Sub

Public Sub TextBoxAll_Click(sender As TextBox) 'Глобальный обработчик клика
    MsgBox "Выбран " & sender.Name
End Sub

Public Sub TextBoxAll_Change(sender As TextBox) 'Глобальный обработчик изменения
    MsgBox "Изменен текст в " & sender.Name
End Sub

Private WithEvents thisTextBox As TextBox 'Храним ссылку на текстовое поле
Private mChangeEventName As String 'Запоминаем названия процедур
Private mClickEventName As String

Public Sub Init(TB As TextBox, Optional ChangeEventName As String = "", Optional ClickEventName As String = "")
    Set thisTextBox = TB
    mChangeEventName = ChangeEventName
    mClickEventName = ClickEventName
End Sub

Private Sub thisTextBox_Change()
    If mChangeEventName <> "" Then
        CallByName thisTextBox.Parent, mChangeEventName, VbMethod, thisTextBox
    End If
End Sub

Private Sub thisTextBox_Click()
    If mClickEventName <> "" Then
        CallByName thisTextBox.Parent, mClickEventName, VbMethod, thisTextBox
    End If
End Sub