Option Explicit

Public Const CONTAINER_ENABLE As Boolean = True
Public Const CONTAINER_DISABLE As Boolean = False

Private Const CONTAINER_FRAME As String = "Frame"
Private Const CONTAINER_PIC_BOX As String = "PictureBox"
Private Const CONTAINER_SSTAB As String = "SSTab"

Public Enum eEnableDisableContainer
    edcDisable = CONTAINER_DISABLE
    edcEnable = CONTAINER_ENABLE
End Enum

Public Sub EnableDisableContainer(ByRef pobjContainer As Control, _
                                  Optional ByVal pblnEnable As eEnableDisableContainer = edcEnable, _
                                  Optional ByVal pintSSTabIndx As Integer)
    
    '******************************************************************************

    '   DESCRIPTION: Enables/disables frames, picture boxes, and SStab tabs including
    '                all the controls they contain.
    '
    '                Frame control example to disable it:
    '
    '                   EnableDisableContainer Frame1, edcDisable
    '
    '                SSTab control example to disable controls at its first tab.
    '
    '                   EnableDisableContainer  SSTab1, edcDisable, 0
    '
    '
    '******************************************************************************

    Dim lngErrNum As Long
    Dim strErrSource As String
    Dim strErrDesc As String

    
    On Error GoTo MethodExit
    
    Dim objControl As Control
    Dim objContainer As Control
   
    Set objContainer = pobjContainer
    
    With objContainer
        
        For Each objControl In .Parent.Controls
            Select Case TypeName(pobjContainer)
                  
                Case CONTAINER_FRAME, CONTAINER_PIC_BOX
                    If objControl.Container.Name = .Name Then
                        objControl.Enabled = pblnEnable
                    End If
                    
                    If TypeName(objControl) = CONTAINER_FRAME Or _
                       TypeName(objControl) = CONTAINER_PIC_BOX Then
                        If objControl.Container.Name = .Name Then
                            EnableDisableContainer objControl, pblnEnable
                        End If
                    End If
                    
                    .Enabled = pblnEnable
                    
                Case CONTAINER_SSTAB
                    
                    If .Tab = pintSSTabIndx Then
                        If objControl.Container.Name = .Name Then
                            objControl.Enabled = pblnEnable
                        End If
                        If TypeName(objControl) = CONTAINER_FRAME Or _
                           TypeName(objControl) = CONTAINER_PIC_BOX Then
                            If objControl.Container.Name = .Name Then
                                EnableDisableContainer objControl, pblnEnable
                            End If
                        End If
                        
                        .TabEnabled(pintSSTabIndx) = pblnEnable
                    End If
                    
                Case Else
                    ' Do nothing since other types of controls are not containers
            End Select
        Next
    
    End With
    
MethodExit:
    Set objContainer = Nothing
    
    If Err.Number <>  0  Then
        MsgBox "Error " & CStr(Err.Number) & " in EnableDisableContainer"
    End If
    
End Sub