Option Explicit

'№№ Функции API №№
Private Declare Function FindFirstFile Lib "kernel32" Alias "FindFirstFileA" (ByVal lpFileName As String, lpFindFileData As WIN32_FIND_DATA) As Long
Private Declare Function FindNextFile Lib "kernel32" Alias "FindNextFileA" (ByVal hFindFile As Long, lpFindFileData As WIN32_FIND_DATA) As Long
Private Declare Function FindClose Lib "kernel32" (ByVal hFindFile As Long) As Long

'№№ Структуры №№
Private Type FILETIME
    dwLowDateTime As Long
    dwHighDateTime As Long
End Type

Private Type WIN32_FIND_DATA
    dwFileAttributes As Long
    ftCreationTime As FILETIME
    ftLastAccessTime As FILETIME
    ftLastWriteTime As FILETIME
    nFileSizeHigh As Long
    nFileSizeLow As Long
    dwReserved0 As Long
    dwReserved1 As Long
    cFileName As String * 260
    cAlternate As String * 14
End Type

'№№ События №№
Public Event EnumerateFile(ByVal sFileName As String)
Public Event EnumerateFolder(ByVal sFolderPath As String)


'№№№  Мощный переборщик файлов в папке и подпапках, возвращает коллекцию полных путей  №№№
' - Очень быстрый способ, рекурсивное прохождение -
Public Function FileCollection(ByVal sPath As String, Optional ByVal sMaskFile As String = "*.*", Optional ByRef FileCollect As Collection) As Collection
    Dim FD As WIN32_FIND_DATA, sFile As String, hFindHandle As Long
    
    If FileCollect Is Nothing Then Set FileCollect = New Collection
    If Right(sPath, 1) <> "\" Then sPath = sPath & "\"
    
    hFindHandle = FindFirstFile(sPath & "*", FD)
    
    If hFindHandle > 0 Then
        Do
            sFile = FD.cFileName
            sFile = Left(sFile, InStr(1, sFile, vbNullChar) - 1)
    
            If sFile <> "." And sFile <> ".." Then
                If (FD.dwFileAttributes And vbDirectory) = vbDirectory Then
                    RaiseEvent EnumerateFolder(sPath & sFile)
                    FileCollection sPath & sFile, sMaskFile, FileCollect
                Else
                    If sFile Like sMaskFile Then
                        RaiseEvent EnumerateFile(sPath & sFile)
                        FileCollect.Add sPath & sFile
                    End If
                End If
            End If
        Loop While FindNextFile(hFindHandle, FD)
        
        FindClose hFindHandle
    End If
    
    Set FileCollection = FileCollect
End Function