function LoadPictureFromStream( Stream: TStream ): TGraphic;
var
  aHeader: Array[ 0 .. 9 ] of AnsiChar;
begin
  Result := nil;

  try
    if Stream.Size < sizeof( aHeader ) then
      Exit;

    Stream.Position := 0;
    Stream.Read( aHeader, sizeof( aHeader ) );

    if ( aHeader[ 0 ] = 'B' ) and ( aHeader[ 1 ] = 'M' ) then begin
      Stream.Position := 0;
      Result := Graphics.TBitmap.Create;
      Result.Transparent := True;
      Result.LoadFromStream( Stream );
    end else if ( aHeader[ 1 ] = 'P' ) and ( aHeader[ 2 ] = 'N' ) and ( aHeader[ 3 ] = 'G' ) then begin
      Stream.Position := 0;
      Result := TPNGObject.Create;
      Result.Transparent := True;
      Result.LoadFromStream( Stream );
    end else if ( aHeader[ 0 ] = 'G' ) and ( aHeader[ 1 ] = 'I' ) and ( aHeader[ 2 ] = 'F' ) then begin
      Stream.Position := 0;
      Result := TGIFImage.Create;
      Result.LoadFromStream( Stream );
    end else if ( aHeader[ 6 ] = 'J' ) and ( aHeader[ 7 ] = 'F' ) and ( aHeader[ 8 ] = 'I' ) and ( aHeader[ 9 ] = 'F' ) then begin
      Stream.Position := 0;
      Result := TJPEGImage.Create;
      Result.LoadFromStream( Stream );
    end else
      Exit;
  except
    FreeAndNil( Result );
  end;
end;