{$A8}
function LoginUser(const ACaption, AMessage: String; var AUserName, APassword: String; var ASavePassword: Boolean): Boolean;
type
  PCredUIInfo = ^TCredUIInfo;
  TCredUIInfo = record
    cbSize: DWORD;
    hwndParent: HWND;
    pszMessageText: PChar;
    pszCaptionText: PChar;
    hbmBanner: HBITMAP;
  end;

var
  Lib: HMODULE;
  CredUIPromptForCredentials: function(pUiInfo: PCredUIInfo; pszTargetName: PChar; pContext: Pointer; dwAuthError: DWORD; pszUserName: PChar; ulUserNameBufferSize: ULONG; pszPassword: PChar; ulPasswordBufferSize: ULONG; var save: BOOL; dwFlags: DWORD): DWORD; stdcall;
  CredInfo: TCredUIInfo;
  User, Password: String;
  Ret: DWORD;
  Save: BOOL;
const
  MAXBUFLEN                                = 10240;  // maximum login and password length in chars
  credui                                   = 'credui.dll';
  CredUIPromptForCredentialsName           = {$IFDEF UNICODE}
                                             'CredUIPromptForCredentialsW'
                                             {$ELSE}
                                             'CredUIPromptForCredentialsA'
                                             {$ENDIF};
  CREDUI_FLAGS_INCORRECT_PASSWORD          = $00001; // indicates the username is valid, but password is not
  CREDUI_FLAGS_DO_NOT_PERSIST              = $00002; // Do not show "Save" checkbox, and do not persist credentials
  CREDUI_FLAGS_REQUEST_ADMINISTRATOR       = $00004; // Populate list box with admin accounts
  CREDUI_FLAGS_EXCLUDE_CERTIFICATES        = $00008; // do not include certificates in the drop list
  CREDUI_FLAGS_REQUIRE_CERTIFICATE         = $00010;
  CREDUI_FLAGS_SHOW_SAVE_CHECK_BOX         = $00040;
  CREDUI_FLAGS_ALWAYS_SHOW_UI              = $00080;
  CREDUI_FLAGS_REQUIRE_SMARTCARD           = $00100;
  CREDUI_FLAGS_PASSWORD_ONLY_OK            = $00200;
  CREDUI_FLAGS_VALIDATE_USERNAME           = $00400;
  CREDUI_FLAGS_COMPLETE_USERNAME           = $00800;
  CREDUI_FLAGS_PERSIST                     = $01000; // Do not show "Save" checkbox, but persist credentials anyway
  CREDUI_FLAGS_SERVER_CREDENTIAL           = $04000;
  CREDUI_FLAGS_EXPECT_CONFIRMATION         = $20000; // do not persist unless caller later confirms credential via CredUIConfirmCredential() api
  CREDUI_FLAGS_GENERIC_CREDENTIALS         = $40000; // Credential is a generic credential
  CREDUI_FLAGS_USERNAME_TARGET_CREDENTIALS = $80000; // Credential has a username as the target
  CREDUI_FLAGS_KEEP_USERNAME               = $100000; // don't allow the user to change the supplied username
begin
  Lib := SafeLoadLibrary(credui);
  if Lib = 0 then
    RaiseLastOSError;
  try
    CredUIPromptForCredentials := GetProcAddress(Lib, CredUIPromptForCredentialsName);
    if not Assigned(CredUIPromptForCredentials) then
      RaiseLastOSError;
    FillChar(CredInfo, SizeOf(CredInfo), 0);
    CredInfo.cbSize := SizeOf(CredInfo);
    if Screen.FocusedForm <> nil then
      CredInfo.hwndParent := Screen.FocusedForm.Handle
    else if Screen.ActiveForm <> nil then
      CredInfo.hwndParent := Screen.ActiveForm.Handle
    else
      CredInfo.hwndParent := 0;
    CredInfo.pszCaptionText := PChar(ACaption);
    CredInfo.pszMessageText := PChar(AMessage);
    User := AUserName + #0;
    Password := APassword + #0;
    Save := ASavePassword;
    SetLength(User, MAXBUFLEN);
    SetLength(Password, MAXBUFLEN);
    Ret := CredUIPromptForCredentials(@CredInfo, nil, nil, 0, PChar(User), MAXBUFLEN, PChar(Password), MAXBUFLEN, Save, CREDUI_FLAGS_ALWAYS_SHOW_UI or CREDUI_FLAGS_DO_NOT_PERSIST or CREDUI_FLAGS_SHOW_SAVE_CHECK_BOX or CREDUI_FLAGS_GENERIC_CREDENTIALS);
    case Ret of
      NO_ERROR:
      begin
        AUser := PChar(User);
        APassword := PChar(Password);
        ASavePassword := Save;
        Result := True;
        Exit;
      end;
      ERROR_CANCELLED:
      begin
        Result := False;
        Exit;
      end;
    else
      SetLastError(Ret);
      RaiseLastOSError;
    end;
  finally
    FreeLibrary(Lib);
  end;
end;