type
  TFormShowType = (fstAppModal, fstParentModal, fstNonModal);

  TParentModalHelper = class
  private
    ModalForm:TForm;
    FormCloseEvent:TCloseEvent;
    FModalState:Boolean;
    procedure FormClose(Sender:TObject;var Action:TCloseAction);
  public
    constructor CreateHelper(AForm:TForm);
    destructor Destroy; override;
    property  InModal:Boolean read FModalState;
 end;

//----------------------------------------------------------------------------------------------------------------------------------------------------
constructor TParentModalHelper.CreateHelper(AForm: TForm);
begin
  inherited Create;
  ModalForm := AForm;
  FormCloseEvent := ModalForm.OnClose;
  ModalForm.OnClose := FormClose;
  FModalState := True;
end;

//----------------------------------------------------------------------------------------------------------------------------------------------------
destructor TParentModalHelper.Destroy;
begin
  ModalForm.OnClose := FormCloseEvent;
  inherited;
end;

//----------------------------------------------------------------------------------------------------------------------------------------------------
procedure TParentModalHelper.FormClose(Sender:TObject; var Action:TCloseAction);
var
  Parent:TCustomForm;
begin
  if Assigned(FormCloseEvent) then FormCloseEvent(Sender,Action);
  FModalState := False;
  if Sender is TCustomForm then
  begin
    Parent := (Sender as TCustomForm).PopupParent;
    if Parent = nil then Exit;
    Parent.Enabled := True;
    Parent.SetFocus;
  end;
end;


//----------------------------------------------------------------------------------------------------------------------------------------------------
function ShowForm(AParent:TCustomForm;AForm:TCustomForm;ShowType:TFormShowType = fstParentModal):TModalResult;
var
  helper: TParentModalHelper;
begin
 Result := mrNone;

 case ShowType of
   fstAppModal:
   begin
     Result := AForm.ShowModal;
    end;

    fstParentModal:
    begin
      helper := nil;
      try
        AForm.PopupMode := pmExplicit;
        AForm.PopupParent := AParent;
        AParent.Enabled := False;
        AForm.Show;
        helper := TParentModalHelper.CreateHelper(TForm(AForm));
        Screen.FocusedForm := AForm;
        while helper.InModal do
        begin
          if Application.Terminated then
          begin
            AForm.Hide;
            Break;
          end;
          Application.HandleMessage;
        end;
      finally
        FreeAndNil(helper);
      end;
      Result := AForm.ModalResult;
    end;

    fstNonModal:
    begin
      AForm.PopupMode := pmNone;
      AForm.Show;
    end;

  end {case};

end;