type
  TIconList = class
  strict private
    type
      TIconSize = record
        Width: Integer;
        Height: Integer;
      end;
      TIconData = TArray<Byte>;
      TIconItem = record
        Data: TIconData;
        Index: Integer;
      end;
      TIconItems = TList<TIconItem>;
    class var
      FCurIdx: Integer;
  strict private
    FIcons: TObjectDictionary<TIconSize, TIconItems>;
  public
    constructor Create;
    destructor Destroy; override;
    function TryAddIcon(const AIcon: TIconData; AWidth, AHeight: Integer;
      out AIndex: Integer): Boolean;
  end;

{ TIconList }

constructor TIconList.Create;
begin
  inherited Create;
  FIcons := TObjectDictionary<TIconSize, TIconItems>.Create([doOwnsValues]);
end;

destructor TIconList.Destroy;
begin
  FIcons.Free;
  inherited Destroy;
end;

function TIconList.TryAddIcon(const AIcon: TIconData; AWidth,
  AHeight: Integer; out AIndex: Integer): Boolean;
var
  LSize: TIconSize;
  LItems: TIconItems;
  LItem: TIconItem;
begin
  LSize.Width := AWidth;
  LSize.Height := AHeight;
  if not FIcons.TryGetValue(LSize, LItems) then begin
    LItems := TIconItems.Create;
    FIcons.Add(LSize, LItems);
  end;
  for LItem in LItems do begin
    if
      (Length(LItem.Data) = Length(AIcon)) and
      CompareMem(LItem.Data, AIcon, Length(AIcon))
    then begin
      AIndex := LItem.Index;
      Result := False;
      Exit;
    end;
  end;
  AIndex := FCurIdx;
  Inc(FCurIdx);
  LItem.Data := AIcon;
  LItem.Index := AIndex;
  LItems.Add(LItem);
  Result := True;
end;

TIconItems = TDictionary<Integer, Integer>;

function TIconList.TryAddIcon(const AIcon: TIconData; AWidth,
  AHeight: Integer; out AIndex: Integer): Boolean;
var
  LSize: TIconSize;
  LItems: TIconItems;
  LHash: Integer;
begin
  LSize.Width := AWidth;
  LSize.Height := AHeight;
  if not FIcons.TryGetValue(LSize, LItems) then begin
    LItems := TIconItems.Create;
    FIcons.Add(LSize, LItems);
  end;
  LHash := THashBobJenkins.GetHashValue(AIcon[0], Length(AIcon));
  if LItems.TryGetValue(LHash, AIndex) then begin
    Result := False;
    Exit;
  end;
  AIndex := FCurIdx;
  Inc(FCurIdx);
  LItems.Add(LHash, AIndex);
  Result := True;
end;