TOwnedHandleStream = class(THandleStream)
  public
    destructor Destroy; override;
  end;

  TNamedHandleStream = class(TOwnedHandleStream)
  strict private
    FName: string;
  public
    constructor Create(AHandle: THandle; const AName: string);
  public
    property Name: string read FName;
  end;

  TCustomFileStream = class(TNamedHandleStream)
  public
    constructor Create(const AFileName: string; AAccess, AShareMode,
      ACreation: Cardinal; AFlagsAndAttributes: Cardinal = FILE_ATTRIBUTE_NORMAL;
      ASecAttr: PSecurityAttributes = nil; ATemplate: Cardinal = 0);
  end;

{ TOwnedHandleStream }

destructor TOwnedHandleStream.Destroy;
begin
  if FHandle <> 0 then
    CloseHandle(FHandle);
  inherited Destroy;
end;

{ TNamedHandleStream }

constructor TNamedHandleStream.Create(AHandle: THandle; const AName: string);
begin
  inherited Create(AHandle);
  FName := AName;
end;

{ TCustomFileStream }

constructor TCustomFileStream.Create(const AFileName: string; AAccess,
  AShareMode, ACreation, AFlagsAndAttributes: Cardinal;
  ASecAttr: PSecurityAttributes; ATemplate: Cardinal);
var
  LHandle: THandle;
begin
  LHandle := CreateFile(
    PChar(AFileName),
    AAccess,
    AShareMode,
    ASecAttr,
    ACreation,
    AFlagsAndAttributes,
    ATemplate
  );
  Win32Check(LHandle <> INVALID_HANDLE_VALUE);
  inherited Create(LHandle, AFileName);
end;