procedure TStrings.LoadFromFile(const FileName: string);
var
Stream: TStream;
begin
Stream := TFileStream.Create(FileName, fmOpenRead or fmShareDenyWrite);
try
LoadFromStream(Stream);
finally
Stream.Free;
end;
end;

procedure TStrings.LoadFromStream(Stream: TStream);
begin
LoadFromStream(Stream, nil);
end;

procedure TStrings.LoadFromStream(Stream: TStream; Encoding: TEncoding);
var
Size: Integer;
Buffer: TBytes;
begin
BeginUpdate;
try
Size := Stream.Size - Stream.Position;
SetLength(Buffer, Size);
Stream.Read(Buffer, 0, Size);
Size := TEncoding.GetBufferEncoding(Buffer, Encoding, FDefaultEncoding);
SetEncoding(Encoding); // Keep Encoding in case the stream is saved
SetTextStr(Encoding.GetString(Buffer, Size, Length(Buffer) - Size));
finally
EndUpdate;
end;
end;

procedure TStrings.SetTextStr(const Value: string);
var
P, PCurVal, PCurLB, PStartVal, PStartLB, PEndLB: PChar;
S: string;
LineBreakLen: Integer;
begin
BeginUpdate;
try
Clear;
P := Pointer(Value);
if P = nil then
Exit;

LineBreakLen := Length(LineBreak);
if LineBreakLen = 0 then
begin
Add(Value);
Exit;
end;

// When LineBreak is:
// * sLineBreak - for compatibility with Windows, Posix and old macOS platforms,
// we handle #13#10, #10 and #13 as it would be #13#10.
// * NOT sLineBreak - we use strict checking for LineBreak.
if CompareStr(LineBreak, sLineBreak) = 0 then
begin
while P^ <> #0 do
begin
PStartVal := P;
while not (P^ in [#0, #10, #13]) do Inc(P);
SetString(S, PStartVal, P - PStartVal);
Add(S);
if P^ = #13 then Inc(P);
if P^ = #10 then Inc(P);
end;
Exit;
end;

PStartLB := Pointer(LineBreak);
PEndLB := PStartLB + LineBreakLen;
PCurLB := PStartLB;
PStartVal := P;

while P^ <> #0 do
begin
while (P^ <> PStartLB^) and (P^ <> #0) do
Inc(P);
if P^ <> #0 then
begin
PCurVal := P + 1;
Inc(PCurLB);
while PCurLB^ <> #0 do
begin
if PCurVal^ <> PCurLB^ then
Break;
Inc(PCurVal);
Inc(PCurLB)
end;
if PCurLB = PEndLB then
begin
SetString(S, PStartVal, P - PStartVal);
Add(S);
P := PCurVal;
PStartVal := P;
end
else
Inc(P);
PCurLB := PStartLB;
end;
end;

if P > PStartVal then
begin
SetString(S, PStartVal, P - PStartVal);
Add(S);
end;
finally
EndUpdate;
end;
end;