procedure TWinControl.RecreateWnd;
begin
  if WindowHandle <> 0 then Perform(CM_RECREATEWND, 0, 0);
end;

procedure TWinControl.CMRecreateWnd(var Message: TMessage);
var
  WasFocused: Boolean;
begin
  WasFocused := Focused;
  UpdateRecreatingFlag(True);
  try
    DestroyHandle;
    UpdateControlState;
  finally
    UpdateRecreatingFlag(False);
  end;
  if WasFocused and (WindowHandle <> 0) then
    Winapi.Windows.SetFocus(WindowHandle);
end;

procedure TCustomTreeView.CreateWnd;
var
  I: Integer;
begin
  FStateChanging := False;
  inherited CreateWnd;
  TreeView_SetBkColor(Handle, ColorToRGB(Color));
  TreeView_SetTextColor(Handle, ColorToRGB(Font.Color));
  if FMemStream <> nil then
  begin
    Items.BeginUpdate;
    try
      Items.ReadNodeData(FMemStream);
      Items.ReadExpandedState(FMemStream);
      FreeAndNil(FMemStream);
      SetTopItem(Items.GetNodeFromIndex(FSaveTopIndex));
      FSaveTopIndex := 0;
      if FSaveIndexes <> nil then
      begin
        for I := 0 to FSaveIndexes.Count - 1 do
          FSelections.Add(Items.GetNodeFromIndex(Integer(FSaveIndexes[I])));
        FreeAndNil(FSaveIndexes);
        ValidateSelection;
        SetSelected(Selections[0]);
      end
      else
      if FSaveIndex <> -1 then
        SetSelected(Items.GetNodeFromIndex(FSaveIndex));
      FSaveIndex := -1;
    finally
      Items.EndUpdate;
    end;
  end;
  if FSaveIndent <> -1 then
    Indent := FSaveIndent;
  if (Images <> nil) and Images.HandleAllocated then
    SetImageList(Images.Handle, TVSIL_NORMAL);
  if (StateImages <> nil) and StateImages.HandleAllocated then
    SetImageList(StateImages.Handle, TVSIL_STATE);
  if StyleServices.Enabled and TOSVersion.Check(6) and StyleServices.IsSystemStyle then
    SetWindowTheme(Handle, 'explorer', nil); // do not localize
end;

procedure TCustomTreeView.DestroyWnd;
var
  Node: TTreeNode;
  I: Integer;
begin
  FStateChanging := True;
  FRClickNode := nil;
  FShiftAnchor := nil;
  if FCreateWndRestores and (Items.Count > 0) and (csRecreating in ControlState) then
  begin
    FMemStream := TMemoryStream.Create;
    Items.WriteNodeData(FMemStream);
    Items.WriteExpandedState(FMemStream);
    FMemStream.Position := 0;
    FSaveTopIndex := 0;
    FSaveIndex := -1;
    Node := GetTopItem;
    if Node <> nil then
      FSaveTopIndex := Node.AbsoluteIndex;
    Items.BeginUpdate;
    try
      if MultiSelect and (FSelections.Count > 1) then
      begin
        FSaveIndexes := TList.Create;
        for I := 0 to FSelections.Count - 1 do
{$IFDEF CLR}
          FSaveIndexes.Add(TObject(TTreeNode(FSelections[I]).AbsoluteIndex));
{$ELSE}
          FSaveIndexes.Add(Pointer(TTreeNode(FSelections[I]).AbsoluteIndex));
{$ENDIF}
        FSelections.Clear;
      end
      else
      begin
        Node := Selected;
        if Node <> nil then
          FSaveIndex := Node.AbsoluteIndex;
      end;
      Items.Clear;
    finally
      Items.EndUpdate;
    end;
  end;
  FSaveIndent := Indent;
  inherited DestroyWnd;
end;

type
  TTreeView = class(Vcl.ComCtrls.TTreeView)
  strict private
    procedure UpdateObjects(ASetNode: Boolean);
  protected
    procedure CreateWnd; override;
    procedure DestroyWnd; override;
  end;

implementation

{ TTreeView }

procedure TTreeView.UpdateObjects(ASetNode: Boolean);
const
  CNullNode: TTreeNode = nil;
var
  LNodePtr: ^TTreeNode;
  LNode: TTreeNode;
  LData: TObject;
  LNodeSup: ITreeNodeSupport;
begin
  if ASetNode then
    LNodePtr := @LNode
  else
    LNodePtr := @CNullNode;

  for LNode in Items do begin
    LData := LNode.Data;
    if LData <> nil then begin
      if not LData.GetInterface(ITreeNodeSupport, LNodeSup) then begin
        raise ETreeViewError.CreateFmt(
          'Class %s is not supported interface ITreeNodeSupport',
          [LData.ClassName]
        );
      end;
      LNodeSup.RecreateNode(LNodePtr^);
    end;
  end;
end;

procedure TTreeView.CreateWnd;
begin
  inherited CreateWnd;
  UpdateObjects(True);
end;

procedure TTreeView.DestroyWnd;
begin
  UpdateObjects(False);
  inherited DestroyWnd;
end;