type
  TResponseCallback = procedure(const URL, S : String) of object;

  THttpThread = class(TThread)
  strict protected
    FHttp : TIdHTTP;
    FUrl  : string;
    FOnResponse : TResponseCallback;
    function GetIsWorking: Boolean; virtual;
  protected
    procedure Execute; override; //Исполнение потока сервера
  public
    constructor Create(const AHttp : TIdHTTP; const AUrl : string); virtual;
    procedure Start; virtual;
    procedure Stop; virtual;
    property IsWorking : Boolean read GetIsWorking;
    property OnResponse  : TResponseCallback read FOnResponse write FOnResponse;
  end;

{ THttpThread }

constructor THttpThread.Create(const AHttp : TIdHTTP; const AUrl : string);
begin
  inherited Create(True);
  FreeOnTerminate := False;
  FHttp := AHttp;
  FUrl := AUrl;
end;

procedure THttpThread.Execute;
var source : TStringStream;
begin
  source := TStringStream.Create('', TUTF8Encoding.Create);
  try
    while not Terminated do begin
      try
        source.Clear;
        FHttp.Post(FUrl, nil, source, nil);
        if Terminated then
          Exit;
      except
        if Terminated then
          Exit;
        raise;
      end;

      if (FHttp.Response.ResponseCode = 200) then begin
        if Assigned(FOnResponse) then begin
          Synchronize(procedure ()
            begin
              FOnResponse(FURL, source.DataString);
            end);
        end;
      end;
    end;
    FHttp.Disconnect;
  finally
    source.Free;
  end;
end;

function THttpThread.GetIsWorking: Boolean;
begin
  Result := Started and not Finished;
end;

procedure THttpThread.Start;
begin
  if not Suspended or IsWorking then //Если поток запущен или уже работает
    Exit; //Выходим

  if Finished then //Если поток уже остановился, то выдаем ошибку
    raise Exception.Create('Поток уже завершен');

  Suspended := false; //Запускаем поток сервера
end;

procedure THttpThread.Stop;
begin
  if not IsWorking then //Поток не работает
    Exit; //выходим

  if Suspended then //Если поток по каким-то причинам остановлен
    Suspended := false; //Возобновляем его работу

  Terminate; //Принудительно устанавливаем флаг остановки потока
  if FHttp.Connected then
    FHttp.Disconnect;
  WaitFor; //Ждем завершение потока
end;