program strdate;

{$APPTYPE CONSOLE}

uses
  SysUtils, DateUtils;

resourcestring
  sSDTFNoFmtString  = 'Не задана строка форматирования даты/времени.';
  sSDTFLengthError  = 'Длина исходной строки меньше заданной форматированием.';
  sSDTFCharMismatch = 'Символ %d строки не соответствует формату.';
  sSDTFNonDigitChar = 'Некорректное числовое значение в позиции %d.';

{ Допустимые символы в Fmt:
    Y - год, M - месяц, D - день;
    h - час, m - минута, s - секунда, z - миллисекунда;
    ? - один любой символ, * - всё, кроме цифр.
    Все остальные символы означают сами себя. }
function StrToDateTimeFmt(const Str, Fmt: string): TDateTime;
var
  P: PChar;   // текущий символ формата
  L: PChar;   // начало текущего блока
  E: Integer; // позиция ощибки преобразования строки в число
  I: Integer; // индекс текущего поля даты и времени
  S: Integer; // смещение текущего поля в исходной строке относительно формата
  D: array [0..6] of Integer; // значения полей даты и времени
begin
  if Fmt = '' then
    raise EConvertError.CreateRes(@sSDTFNoFmtString);
  if Length(Str) < Length(Fmt) then
    raise EConvertError.CreateRes(@sSDTFLengthError);
  I := 0; // не требуется, но компилятор тупит и ругается на not initialized.
  S := 1; // начинается с 1 для компенсации индексации строк
  P := PChar(Pointer(Fmt));
  L := P;
  FillChar(D, SizeOf(D), $00);
  repeat
    if P^ <> L^ then begin
      case L^ of
        'Y': I := 0;
        'M': I := 1;
        'D': I := 2;
        'h': I := 3;
        'm': I := 4;
        's': I := 5;
        'z': I := 6;
        '*': begin
               I := P - PChar(Pointer(Fmt));
               while not (Str[I + S] in ['0'..'9']) do Inc(S);
               if Length(Str) - S + 1 < Length(Fmt) - (P - L) then
                 raise EConvertError.CreateRes(@sSDTFLengthError);
               L := P;
               Inc(P);
               Continue;
             end;
      else
        if (L^ <> '?') and (Str[L - PChar(Pointer(Fmt)) + S] <> L^) then
          raise EConvertError.CreateResFmt(@sSDTFCharMismatch, [L - PChar(Pointer(Fmt)) + S])
        else begin
          L := P;
          Inc(P);
          Continue;
        end;
      end;
      Val(Copy(Str, L - PChar(Pointer(Fmt)) + S, P - L), D[I], E);
      if E > 0 then
        raise EConvertError.CreateResFmt(@sSDTFNonDigitChar, [L - PChar(Pointer(Fmt)) + E + S - 1]);
      L := P;
    end;
    Inc(P);
  until (P - 1)^ = #0;
  Result := EncodeDateTime(D[0], D[1], D[2], D[3], D[4], D[5], D[6]);
end;

var
  d: TDateTime;
begin
  d := StrToDateTimeFmt('[20150312] <13:10:24.346>', '?YYYYMMDD*mm:hh:ss.zzz>');
  Writeln(FormatDateTime('DD.MM.YYYY hh:mm:ss (zzz)', d));
  ReadLn;
end.