unit Unit1;

{$O+}

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Label1: TLabel;
    Label2: TLabel;
    Label3: TLabel;
    procedure Button1Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

type
  TMixFunc = function ( w1, w2 : word ) : dWord;

function MixNop( w1, w2 : word ) : dWord; assembler; register;
asm
     Nop
end;

function MixAsm( w1, w2 : word ) : dWord; assembler; register;
asm
     Push    EBX

     Xor     EBX,    EBX    // обнуляем временный результат
     Mov     ECX,    01h    // устанавливаем маску единичного бита

@@10:
     Test    EAX,    01h    // проверяем бит для w1
     Jz      @@20

     Or      EBX,    ECX    // устанавливаем единичный бит w1

@@20:
     Shl     ECX,    01h    // сдвигаем маску единичного бита для w2
     Test    EDX,    01h    // проверяем бит для w2
     Jz      @@30

     Or      EBX,    ECX    // устанавливаем единичный бит w2

@@30:
     Shr     EAX,    01h    // сдвигаем w1 для проверки следующего бита
     Shr     EDX,    01h    // сдвигаем w2 для проверки следующего бита

     Shl     ECX,    01h    // сдвигаем маску единичного бита для w1
     Jecxz   @@40

     Jmp     @@10

@@40:
     Mov     EAX,    EBX

     Pop     EBX
end;

function MixPas( w1, w2 : word ) : dWord;
// реализация alekcvp
var
  i : integer;
  Mask : dWord;
begin
  Result := 0;
  for i := 15 downto 0 do
  begin
    Mask := 1 shl i;
    Result := Result shl 1 or DWORD(w1 and Mask) shl 1 or DWORD(w2 and Mask);
  end;
end;

function MixPlane(w1, w2 : word ) : dWord;
// реализация SoftForYou
var
  X: Cardinal;
begin
  X := (Cardinal(w2) shl 16) + Cardinal(w1);

  Result := Cardinal(w1) and (1 shl 0);
  Inc(Result, (X and (1 shl 1)) shl 1);
  Inc(Result, (X and (1 shl 2)) shl 2);
  Inc(Result, (X and (1 shl 3)) shl 3);
  Inc(Result, (X and (1 shl 4)) shl 4);
  Inc(Result, (X and (1 shl 5)) shl 5);
  Inc(Result, (X and (1 shl 6)) shl 6);
  Inc(Result, (X and (1 shl 7)) shl 7);
  Inc(Result, (X and (1 shl 8)) shl 8);
  Inc(Result, (X and (1 shl 9)) shl 9);
  Inc(Result, (X and (1 shl 10)) shl 10);
  Inc(Result, (X and (1 shl 11)) shl 11);
  Inc(Result, (X and (1 shl 12)) shl 12);
  Inc(Result, (X and (1 shl 13)) shl 13);
  Inc(Result, (X and (1 shl 14)) shl 14);
  Inc(Result, (X and (1 shl 15)) shl 15);
  Inc(Result, (X and (1 shl (16 + 0))) shr (16 + 0 - 1));
  Inc(Result, (X and (1 shl (16 + 1))) shr (16 + 1 - 1));
  Inc(Result, (X and (1 shl (16 + 2))) shr (16 + 2 - 1));
  Inc(Result, (X and (1 shl (16 + 3))) shr (16 + 3 - 1));
  Inc(Result, (X and (1 shl (16 + 4))) shr (16 + 4 - 1));
  Inc(Result, (X and (1 shl (16 + 5))) shr (16 + 5 - 1));
  Inc(Result, (X and (1 shl (16 + 6))) shr (16 + 6 - 1));
  Inc(Result, (X and (1 shl (16 + 7))) shr (16 + 7 - 1));
  Inc(Result, (X and (1 shl (16 + 8))) shr (16 + 8 - 1));
  Inc(Result, (X and (1 shl (16 + 9))) shr (16 + 9 - 1));
  Inc(Result, (X and (1 shl (16 + 10))) shr (16 + 10 - 1));
  Inc(Result, (X and (1 shl (16 + 11))) shr (16 + 11 - 1));
  Inc(Result, (X and (1 shl (16 + 12))) shr (16 + 12 - 1));
  Inc(Result, (X and (1 shl (16 + 13))) shr (16 + 13 - 1));
  Inc(Result, (X and (1 shl (16 + 14))) shr (16 + 14 - 1));
  Inc(Result, (X and (1 shl (16 + 15))) shr (16 + 15 - 1));
end;

procedure TForm1.Button1Click(Sender: TObject);
var
  Nop : Int64;

  function Exec( Mix : TMixFunc ) : Int64;
  var
    t1, t2 : Int64;
    i : integer;
  begin
    QueryPerformanceCounter( t1 );
    for i := 1 to 1000000 do
      Mix( $1234, $4321 );
    QueryPerformanceCounter( t2 );
    Result := t2 - t1;
  end;

begin
  Nop := Exec( MixNop );
  Label1.Caption := 'Asm: ' + IntToStr( Exec( MixAsm ) - Nop );
  Label2.Caption := 'Pas: ' + IntToStr( Exec( MixPas ) - Nop );
  Label3.Caption := 'Plane: ' + IntToStr( Exec( MixPlane ) - Nop );
end;