function DllInstall(bInstall: WordBool; pszCmdLine: LPCWSTR): HResult; stdcall;
var
  SavePerUserVal: Boolean;
begin
  SavePerUserVal := ComServer.PerUserRegistration;
  if StrIComp(pszCmdLine, PWideChar('user')) = 0 then
    ComServer.PerUserRegistration := True
  else
    ComServer.PerUserRegistration := False;
  if (bInstall) then
  begin
    Result := DllRegisterServer();
    if Result = E_FAIL then
      DllUnregisterServer();
  end
  else
    Result := DllUnregisterServer();
  ComServer.PerUserRegistration := SavePerUserVal;
end;

function DllUnregisterServer: HResult;
begin
  Result := S_OK;
  try
    ComServer.UpdateRegistry(False);
  except
    Result := E_FAIL;
  end;
end;

procedure TComServer.UpdateRegistry(Register: Boolean);
begin
  if FTypeLib <> nil then
    if Register then
      RegisterTypeLibrary(FTypeLib, GetModuleFileName, PerUserRegistration)
    else
      UnregisterTypeLibrary(FTypeLib, PerUserRegistration);
  FRegister := Register;
  ComClassManager.ForEachFactory(Self, FactoryUpdateRegistry);
end;

procedure TComObjectFactory.UpdateRegistry(Register: Boolean);
const
  ThreadStrs: array[TThreadingModel] of string =
    ('', 'Apartment', 'Free', 'Both', 'Neutral');
var
  ClassID, ProgID, ServerKeyName, ShortFileName, RegPrefix: string;
  RootKey: HKEY;
begin
  if FInstancing = ciInternal then
    Exit;

  ComServer.GetRegRootAndPrefix(RootKey, RegPrefix);

  ClassID := GUIDToString(FClassID);
  ProgID := GetProgID;
  ServerKeyName := RegPrefix + 'CLSID\' + ClassID + '\' + FComServer.ServerKey;
  if Register then
  begin
    CreateRegKey(RegPrefix + 'CLSID\' + ClassID, '', Description, RootKey);
    ShortFileName := FComServer.ServerFileName;
    if AnsiPos(' ', ShortFileName) <> 0 then
      ShortFileName := ExtractShortPathName(ShortFileName);
    CreateRegKey(ServerKeyName, '', ShortFileName, RootKey);
    if (FThreadingModel <> tmSingle) and IsLibrary then
      CreateRegKey(ServerKeyName, 'ThreadingModel', ThreadStrs[FThreadingModel], RootKey);
    if ProgID <> '' then
    begin
      CreateRegKey(RegPrefix + ProgID, '', Description, RootKey);
      CreateRegKey(RegPrefix + ProgID + '\Clsid', '', ClassID, RootKey);
      CreateRegKey(RegPrefix + 'CLSID\' + ClassID + '\ProgID', '', ProgID, RootKey);
    end;
  end
  else
  begin
    if ProgID <> '' then
    begin
      DeleteRegKey(RegPrefix + 'CLSID\' + ClassID + '\ProgID', RootKey);
      DeleteRegKey(RegPrefix + ProgID + '\Clsid', RootKey);
      DeleteRegKey(RegPrefix + ProgID, RootKey);
    end;
    DeleteRegKey(ServerKeyName, RootKey);
    DeleteRegKey(RegPrefix + 'CLSID\' + ClassID, RootKey);
  end;
end;

function DllRegisterServer: HResult;
begin
  Result := RegisterWizard(TRTWizard.IdentyString);
end;

function RegisterWizard(const AIdenty: String): HResult;
begin
  try
    with TRegistry.Create do
    try
      RootKey := CexpRootKey;
      if KeyExists(CBDSRegKey) and OpenKey(CBDSRegKey + CexpRegKey, True) then begin
        WriteString(AIdenty, SysUtils.GetModuleName(HInstance));
        CloseKey;
        Result := S_OK;
      end else begin
        MessageBox(0, 'Delphi ' + CDelphiVersion + ' not installed', nil, MB_OK or MB_ICONERROR);
        Result := E_ABORT;
      end;
    finally
      Free;
    end;
  except
    Result := E_UNEXPECTED
  end;
end;