TGenericUtils<T> = record
  strict private
    class procedure UnknownType; static;
    class procedure UnsupportedType; static;
  public
    class procedure VarToT(const AVar: Variant; out AOutVal: T); static;
  end;

class procedure TGenericUtils<T>.VarToT(const AVar: Variant; out AOutVal: T);
begin
  case PTypeInfo(TypeInfo(T))^.Kind of
    tkInteger: begin
      if VarIsUnsigned(AVar) then begin
        case SizeOf(T) of
          SizeOf(Byte): PByte(@AOutVal)^ := AVar;
          SizeOf(Word): PWord(@AOutVal)^ := AVar;
          SizeOf(Cardinal): PCardinal(@AOutVal)^ := AVar;
        else
          UnknownType;
        end;
      end else begin  // Is not unsigned
        case SizeOf(T) of
          SizeOf(ShortInt): PShortInt(@AOutVal)^ := AVar;
          SizeOf(SmallInt): PSmallInt(@AOutVal)^ := AVar;
          SizeOf(Integer): PInteger(@AOutVal)^ := AVar;
        else
          UnknownType;
        end;
      end;
    end;
    tkFloat: begin
      case SizeOf(T) of
        SizeOf(Single): PSingle(@AOutVal)^ := AVar;
        SizeOf(Double): PDouble(@AOutVal)^ := AVar;
        SizeOf(Extended): PExtended(@AOutVal)^ := AVar;
      else
        UnknownType;
      end;
    end;
    tkString: PShortString(@AOutVal)^ := ShortString(AVar);
    tkLString: PAnsiString(@AOutVal)^ := AnsiString(AVar);
    tkWString: PWideString(@AOutVal)^ := AVar;
    tkVariant: PVariant(@AOutVal)^ := AVar;
    tkInt64: begin
      if VarIsUnsigned(AVar) then
        PUInt64(@AOutVal)^ := AVar
      else
        PInt64(@AOutVal)^ := AVar;
    end;
    tkUString: PUnicodeString(@AOutVal)^ := AVar;
  else
    UnsupportedType;
  end;
end;