type
  // Ex.: TSomeClass<T>.GetItemPtr: Ptr<T>.P
  Ptr<T> = class
  public
  type
    P = ^T;
  end;

  TArrHelper<T> = class
  public
    class procedure Delete(var Arr: TArray<T>; Index: Integer);
    class procedure Insert(var Arr: TArray<T>; Index: Integer; const Item: T);
    class procedure Add(var Arr: TArray<T>; const Item: T); overload; inline;
    class procedure Add(var Arr: TArray<T>; const ArrToAdd: TArray<T>); overload;
    class procedure Grow(var Arr: TArray<T>; GrowSize: integer = 1); inline;
    class procedure Trunc(var Arr: TArray<T>; TruncSize: Integer = 1); inline;
    class function Add(var Arr: TArray<T>): Ptr<T>.P; overload;
    class function SetLength1(var Arr: TArray<T>): Ptr<T>.P; overload;
    class function GrowR(var Arr: TArray<T>; GrowSize: integer = 1): integer; inline;
    class function TruncR(var Arr: TArray<T>; TruncSize: Integer = 1): integer; inline;
    class function First(var Arr: TArray<T>): T; inline;
    class function FirstPtr(var Arr: TArray<T>): Ptr<T>.P; inline;
    class function Last(var Arr: TArray<T>): T; inline;
    class function LastPtr(var Arr: TArray<T>): Ptr<T>.P; inline;
    class function InArray(var Arr: TArray<T>; const Item: T; DelItem: boolean = False): boolean;
  end;


{ TArrHelper<T> }

// Удалить из массива Arr элемент с индексом Index и уменьшить длину массива
class procedure TArrHelper<T>.Delete(var Arr: TArray<T>; Index: Integer);
var Tail: Integer;
begin
  Finalize(Arr[Index]); // обязательно для управляемых типов (строки, динмассивы, интерфейсы)
  // Теоретически, для Index = High(Arr) (последний элемент) проверка не обязательна,
  // т.к. (High(Arr)-Index) = 0 и никакого копирования не выполнится, но при включенной
  // проверке границ FArr[Index+1] вызовет ошибку
  Tail := High(Arr) - Index;
  if Tail > 0 then
  begin
    Move(Arr[Index+1], Arr[Index], Tail*SizeOf(T));
    // В случае ссылочных типов (строки, динмассивы, интерфейсы) теперь две последних ячейки
    // ссылаются на один и тот же объект, но счетчик не увеличился. Затираем последнюю ячейку.
    FillChar(Arr[High(Arr)], SizeOf(T), 0);
  end;
  Trunc(Arr);
end;

// Проверить наличие элемента в массиве, дополнительно можно его сразу же удалить
class function TArrHelper<T>.InArray(var Arr: TArray<T>; const Item: T; DelItem: boolean = False): boolean;
var
 i: integer;
begin
 Result := False;
 for i := 0 to High(Arr) do
  if TComparer<T>.Default.Compare(Arr[i], Item) = 0 then
  begin
   if DelItem then
    Delete(Arr, i);
   Exit(True);
  end;
end;

class procedure TArrHelper<T>.Insert(var Arr: TArray<T>; Index: Integer; const Item: T);
var Tail: Integer;
begin
  Grow(Arr);
  // Вычисляем кол-во сдвигаемых элементов, избегая range check и лишнего захода
  // при вставке в конец.
  Tail := High(Arr) - Index;
  if Tail > 0 then
  begin
    Move(Arr[Index], Arr[Index+1], Tail*SizeOf(T));
    // В случае ссылочных типов (строки, динмассивы, интерфейсы) теперь две ячейки
    // ссылаются на один и тот же объект, но счетчик не увеличился. Затираем лишнюю ячейку.
    FillChar(Arr[Index], SizeOf(T), 0);
  end;
  Arr[Index] := Item;
end;

// Увеличить длину массива
class procedure TArrHelper<T>.Grow(var Arr: TArray<T>; GrowSize: integer = 1);
begin
  SetLength(Arr, Length(Arr) + GrowSize);
end;

// Увеличить длину массива и вернуть индекс последнего элмента
class function TArrHelper<T>.GrowR(var Arr: TArray<T>; GrowSize: integer): integer;
begin
  SetLength(Arr, Length(Arr) + GrowSize);
  Result := High(Arr);
end;

// Уменьшить длину массива
class procedure TArrHelper<T>.Trunc(var Arr: TArray<T>; TruncSize: Integer = 1);
begin
  SetLength(Arr, Length(Arr) - TruncSize);
end;

// Уменьшьть длину массива и вернуть индекс последнего элмента
class function TArrHelper<T>.TruncR(var Arr: TArray<T>; TruncSize: Integer): integer;
begin
  SetLength(Arr, Length(Arr) - TruncSize);
  Result := High(Arr);
end;

// Добавить в конец массива Arr элемент Item
class procedure TArrHelper<T>.Add(var Arr: TArray<T>; const Item: T);
var
  Len: Integer;
begin
  Len := Length(Arr);
  SetLength(Arr, Len + 1);
  Arr[Len] := Item;
end;

// Добавить в конец массива Arr все элементы из массива ArrToAdd
class procedure TArrHelper<T>.Add(var Arr: TArray<T>; const ArrToAdd: TArray<T>);
var
  Len, i: Integer;
begin
  Len := Length(Arr);
  SetLength(Arr, Len + Length(ArrToAdd));
  for i := Low(ArrToAdd) to High(ArrToAdd) do
    Arr[Len + i] := ArrToAdd[i];
end;

// Увеличить массив Arr на 1 и вернуть указатель на последний элемент
// Варианты применения:
//   1) pItem := TArrHelper<TItem>.Add(ItemArray);
//      pItem.Field := ...
//   2) TArrHelper<TItem>.Add(ItemArray).Field := ...
class function TArrHelper<T>.Add(var Arr: TArray<T>): Ptr<T>.P;
var
  Len: Integer;
begin
  Len := Length(Arr);
  SetLength(Arr, Len + 1);
  Result := @Arr[Len];
end;

// Получить копию первого элемента
class function TArrHelper<T>.First(var Arr: TArray<T>): T;
begin
  Result := Arr[Low(Arr)];
end;

// Получить указатель на первый элемент
class function TArrHelper<T>.FirstPtr(var Arr: TArray<T>): Ptr<T>.P;
begin
  Result := @Arr[Low(Arr)];
end;

// Получить копию последнего элемента
class function TArrHelper<T>.Last(var Arr: TArray<T>): T;
begin
  Result := Arr[High(Arr)];
end;

// Получить указатель на последний элемент
class function TArrHelper<T>.LastPtr(var Arr: TArray<T>): Ptr<T>.P;
begin
  Result := @Arr[High(Arr)];
end;

// Установить размер массива в 1 и вернуть указатель на единственный элемент
class function TArrHelper<T>.SetLength1(var Arr: TArray<T>): Ptr<T>.P;
begin
  SetLength(Arr, 1);
  Result := @Arr[0];
end;