procedure TForm1.FormCreate(Sender: TObject);
const
  CFileName = 'Square.png';
  CFileNameNew = 'SquareNew.png';
  CDelta = 20;
var
  LPicture: TPicture;
  LBmp1: TBitmap;
  LBmp2: TBitmap;
  LPng: TPngImage;
begin
  LPicture := TPicture.Create;
  try
    LPicture.LoadFromFile(CFileName);
    LBmp1 := TBitmap.Create;
    try
      LBmp1.Assign(LPicture.Graphic);
      LBmp2 := TBitmap.Create;
      try
        LBmp2.SetSize(LBmp1.Width + CDelta, LBmp1.Height + CDelta);
        LBmp2.TransparentColor := LBmp1.TransparentColor;
        LBmp2.Transparent := LBmp1.Transparent;
        LBmp2.Canvas.Brush.Color := LBmp2.TransparentColor;
        LBmp2.Canvas.Brush.Style := bsSolid;
        LBmp2.Canvas.FillRect(Rect(0, 0, LBmp2.Width, LBmp2.Height));
        Win32Check(StretchBlt(
          LBmp2.Canvas.Handle,
          CDelta div 2,
          CDelta div 2,
          LBmp1.Width,
          LBmp1.Height,
          LBmp1.Canvas.Handle,
          0,
          0,
          LBmp1.Width,
          LBmp1.Height,
          SRCCOPY
        ));
        LBmp2.Canvas.Pen.Color := clGreen;
        LBmp2.Canvas.Pen.Width := 2;
        LBmp2.Canvas.Brush.Style := bsClear;
        LBmp2.Canvas.Rectangle(0, 0, LBmp2.Width, LBmp2.Height);
        LPng := TPngImage.Create;
        try
          LPng.Assign(LBmp2);
          LPng.SaveToFile(CFileNameNew);
        finally
          LPng.Free;
        end;
      finally
        LBmp2.Free;
      end;
    finally
      LBmp1.Free;
    end;
  finally
    LPicture.Free;
  end;
end;

procedure TForm1.Button1Click(Sender: TObject);
var
  LPng1: TPngImage;
  LPng2: TPngImage;
  LBmp: TBitmap;
begin
  LPng1 := TPngImage.Create;
  try
    LPng1.LoadFromFile(CFileName);
    LBmp := TBitmap.Create;
    try
      LBmp.Assign(LPng1);
      LPng2 := TPngImage.Create;
      try
        LPng2.Assign(LBmp);
        LPng2.SaveToFile(CFileNameNew);
      finally
        LPng2.Free;
      end;
    finally
      LBmp.Free;
    end;
  finally
    LPng1.Free;
  end;
end;

procedure TForm1.Button2Click(Sender: TObject);
var
  LPng1: TPngImage;
  LPng2: TPngImage;
begin
  LPng1 := TPngImage.Create;
  try
    LPng1.LoadFromFile(CFileName);
    LPng2 := TPngImage.CreateBlank(
      LPng1.Header.ColorType,
      LPng1.Header.BitDepth,
      LPng1.Width + CDelta,
      LPng1.Height + CDelta
    );
    try
      LPng2.Canvas.Brush.Color := LPng2.TransparentColor;
      LPng2.Canvas.Brush.Style := bsSolid;
      LPng2.Canvas.FillRect(Rect(0, 0, LPng2.Width, LPng2.Height));
      Win32Check(StretchBlt(
        LPng2.Canvas.Handle,
        CDelta div 2,
        CDelta div 2,
        LPng1.Width,
        LPng1.Height,
        LPng1.Canvas.Handle,
        0,
        0,
        LPng1.Width,
        LPng1.Height,
        SRCCOPY
      ));
      LPng2.Canvas.Pen.Color := clGreen;
      LPng2.Canvas.Pen.Width := 2;
      LPng2.Canvas.Brush.Style := bsClear;
      LPng2.Canvas.Rectangle(0, 0, LPng2.Width, LPng2.Height);
    finally
      LPng2.Free;
    end;
  finally
    LPng1.Free;
  end;
end;

procedure CopyChunk(APngSrc, APngDst: TPngImage; AChunkClass: TChunkClass);
var
  LChunkSrc: TChunk;
  LChunkDst: TChunk;
begin
  LChunkSrc := APngSrc.Chunks.ItemFromClass(AChunkClass);
  if LChunkSrc <> nil then begin
    LChunkDst := APngDst.Chunks.ItemFromClass(AChunkClass);
    if LChunkDst = nil then
      LChunkDst := APngDst.Chunks.Add(AChunkClass);
    LChunkDst.Assign(LChunkSrc);
  end;
end;

procedure TForm1.Button2Click(Sender: TObject);
var
  LPng1: TPngImage;
  LPng2: TPngImage;
  LTRNSSrc: TChunk;
  LTRNSDst: TChunk;
begin
  LPng1 := TPngImage.Create;
  try
    LPng1.LoadFromFile(CFileName);
    LPng2 := TPngImage.CreateBlank(
      LPng1.Header.ColorType,
      LPng1.Header.BitDepth,
      LPng1.Width + CDelta,
      LPng1.Height + CDelta
    );
    try
      CopyChunk(LPng1, LPng2, TChunktRNS);
      CopyChunk(LPng1, LPng2, TChunkPLTE);
      CopyChunk(LPng1, LPng2, TChunkgAMA);

      Win32Check(StretchBlt(
        LPng2.Canvas.Handle,
        CDelta div 2,
        CDelta div 2,
        LPng1.Width,
        LPng1.Height,
        LPng1.Canvas.Handle,
        0,
        0,
        LPng1.Width,
        LPng1.Height,
        SRCCOPY
      ));
      LPng2.SaveToFile(CFileNameNew);
    finally
      LPng2.Free;
    end;
  finally
    LPng1.Free;
  end;
end;

function GetGDIpEncoder(AMimeType: PWideChar): TGUID;
var
  LEncCnt, LEncSize: Cardinal;
  LCodecs: PImageCodecInfo;
  LCurCodec: PImageCodecInfo;
  Li: Cardinal;
begin
  GPCheck(GdipGetImageEncodersSize(LEncCnt, LEncSize));
  GetMem(LCodecs, LEncSize);
  try
    GPCheck(GdipGetImageEncoders(LEncCnt, LEncSize, LCodecs));
    LCurCodec := LCodecs;
    for Li := 1 to LEncCnt do begin
      if StrIComp(LCurCodec^.MimeType, AMimeType) = 0 then
        Exit(LCurCodec^.Clsid);
      Inc(LCurCodec);
    end;
  finally
    FreeMem(LCodecs);
  end;
  Result := TGUID.Empty;
end;

procedure TForm1.Button4Click(Sender: TObject);
var
  LToken: Cardinal;
  LStartup: TGdiplusStartupInput;
  LSrcImg: GpImage;
  LDstBmp: GpBitmap;
  LGraphics: GpGraphics;
  LPen: GpPen;
  LWidth, LHeight: Cardinal;
  LPixelFormat: TPixelFormat;
  LPngEncoder: TGUID;
begin
  FillChar(LStartup, SizeOf(LStartup), 0);
  LStartup.GdiplusVersion := 1;
  GPCheck(GdiplusStartup(LToken, @LStartup, nil));
  try
    GPCheck(GdipLoadImageFromFile(CFileName, LSrcImg));
    try
      GPCheck(GdipGetImageWidth(LSrcImg, LWidth));
      GPCheck(GdipGetImageHeight(LSrcImg, LHeight));
      GPCheck(GdipGetImagePixelFormat(LSrcImg, LPixelFormat));  // LPixelFormat = PixelFormat32bppARGB
      GPCheck(GdipCreateBitmapFromScan0(
        LWidth + CDelta,
        LHeight + CDelta,
        0,
        LPixelFormat,
        nil,
        LDstBmp
      ));
      try
        GPCheck(GdipGetImageGraphicsContext(LDstBmp, LGraphics));
        try
          GPCheck(GdipDrawImageI(LGraphics, LSrcImg, CDelta div 2, CDelta div 2));
          GPCheck(GdipCreatePen1(ALPHA_MASK or clGreen, 5, UnitPixel, LPen));
          try
            GPCheck(GdipDrawRectangleI(LGraphics, LPen, 0, 0, LWidth + CDelta, LHeight + CDelta));
          finally
            GPCheck(GdipDeletePen(LPen));
          end;
        finally
          GPCheck(GdipDeleteGraphics(LGraphics));
        end;
        LPngEncoder := GetGDIpEncoder('image/png');
        GPCheck(GdipSaveImageToFile(LDstBmp, CFileNameNew, @LPngEncoder, nil));
      finally
        GPCheck(GdipDisposeImage(LDstBmp));
      end;
    finally
      GPCheck(GdipDisposeImage(LSrcImg));
    end;
  finally
    GdiplusShutdown(LToken);
  end;
end;