program Project1;

{$APPTYPE CONSOLE}

procedure someProc(AParams : array of const);
begin

 for var i := 0 to High(AParams) do
  case AParams[i].VType of

   vtInteger       : WriteLn('#', i:3, 'Integer ':15, AParams[i].VInteger);
   vtAnsiString    : WriteLn('#', i:3, 'AnsiString ':15, '"', AnsiString(AParams[i].VAnsiString), '"');
   vtUnicodeString : WriteLn('#', i:3, 'UnicodeString ':15, '"', UnicodeString(AParams[i].VUnicodeString), '"');

  end;

end;

procedure FinalizeVarRec(Var AVarRec : TVarRec);
begin

 case AVarRec.VType of
  vtAnsiString    : AnsiString(AVarRec.VAnsiString) := '';
  vtUnicodeString : UnicodeString(AVarRec.VUnicodeString) := '';
 end;

end;

var

 params : array of TVarRec;

begin

 SetLength(params, 3);

 params[0].VType    := vtInteger;
 params[0].VInteger := 1024;

 params[1].VType                   := vtAnsiString;
 AnsiString(params[1].VAnsiString) := 'AnsiString. Hello!';

 params[2].VType                         := vtUnicodeString;
 UnicodeString(params[2].VUnicodeString) := 'Unicode string. Привет!';

 someProc(params);

 for var i := 0 to High(params) do
  FinalizeVarRec(params[i]);

 ReadLn;

end.

program Project2;

{$APPTYPE CONSOLE}

uses
 System.SysUtils, System.Variants;

procedure someProc(const AParams : array of const);
begin
 for var i := 0 to High(AParams) do
  WriteLn(VarTypeAsText(PVarData(AParams[i].VVariant).VType):15, ' "', VarToStrDef(PVariant(AParams[i].VVariant)^, 'whoops'), '"');
end;

var

 vparams : array of Variant;
 params : array of TVarRec;

begin

 SetLength(vparams, 5);
 SetLength(params, Length(vparams));

 for var i := 0 to high(Params) do
  begin
   params[i].VType := vtVariant;
   params[i].VVariant := @vparams[i];
  end;

 // vparams[n] := FieldByName('xxx').AsVariant;
 vparams[0] := Integer(1024);
 vparams[1] := Now();
 vparams[2] := 'hello';
 vparams[3] := StrToCurr('10.56');
 vparams[4] := pi;

 someProc(params);

 ReadLn;

end.