function compressClobMessage(p_message IN CLOB)
    return BLOB IS
    l_original_blob      BLOB;
    l_compressed_blob    BLOB;
    v_dest_offset NUMBER := 1;
    v_src_offset NUMBER := 1;
    v_amount INTEGER := dbms_lob.lobmaxsize;
    v_blob_csid NUMBER := dbms_lob.default_csid;
    v_lang_ctx INTEGER := dbms_lob.default_lang_ctx;
    v_warning INTEGER;
    BEGIN
      if p_message is null then
        return null;
      end if;
      --
      DBMS_LOB.CREATETEMPORARY(lob_loc=>l_original_blob, cache=>TRUE);
      DBMS_LOB.CREATETEMPORARY(lob_loc=>l_compressed_blob, cache=>TRUE);
      --
      begin
        DBMS_LOB.CONVERTTOBLOB(l_original_blob,p_message,v_amount,v_dest_offset,v_src_offset,v_blob_csid,v_lang_ctx,v_warning);
        if v_warning <> DBMS_LOB.NO_WARNING then
          RAISE_APPLICATION_ERROR(-20001, 'Character in source cannot be properly converted to BLOB!');
        end if;
        UTL_COMPRESS.lz_compress (src => l_original_blob, dst => l_compressed_blob);
        exception
        when others then
        DBMS_LOB.FREETEMPORARY(l_original_blob);
        DBMS_LOB.FREETEMPORARY(l_compressed_blob);
        raise;
      end;
      --
      DBMS_LOB.FREETEMPORARY(l_original_blob);
      return l_compressed_blob;
    end compressClobMessage;