create table ANB_Compound_Trg_Test_Table
(
  id integer not null
 ,S01 varchar2(64)
 ,S02 varchar2(64)
 ,S03 varchar2(64)
 ,S04 varchar2(64)
 ,D01 date
 ,D02 date
 ,D03 date
 ,D04 date
 ,N01 number
 ,N02 number
 ,N03 number
 ,N04 number
)
tablespace TBS_Qrm_Data
/

create or replace trigger Trg$Cmp$ANB_Compound_Trg_Test_Table
for update or delete or insert on ANB_Compound_Trg_Test_Table
compound trigger

  -- Индекс
  v_Index binary_integer := 0;

  -- Строка с изменениями
  type T_Rec is record
  (
    Operation varchar2(4)-- Это чисто для примера и наглядности
    -- На самом деле триггер срабатывает на каждый оператор отдельно и везде доступны inserting, updating, deleting
    -- merge вызывает триггер 2 раза : сначала на insert, потом на update
    -- То есть это поле в массиве изменений не нужно
   ,R_Old ANB_Compound_Trg_Test_Table%rowtype
   ,R_New ANB_Compound_Trg_Test_Table%rowtype
  );

  -- Коллекция изменений
  type T_Table is table of T_Rec index by binary_integer;

  -- Переменные для строки и коллекции
  v_R T_Rec;
  v_T T_Table;

  before statement
  is
  begin
    -- v_T.delete; -- Это необязательно, т.к. каждый оператор сбрасывает внутренние переменные
    null;
  end before statement;
  
  before each row is
  begin
    -- Запоминать будем уже готовые поля
    null;
  end before each row;
  
  after each row
  is
  begin
    -- Запоминать будем уже готовые поля

    -- Индекс
    v_Index := v_Index + 1;

    -- Набьем строку
    v_R := null;
    if inserting then
      v_R.Operation := 'I';
    elsif updating then
      v_R.Operation := 'U';
    else
      v_R.Operation := 'D';
    end if;

    -- Запись до изменения
    v_R.R_Old.ID := :Old.ID;
    v_R.R_Old.S01 := :Old.S01;
    v_R.R_Old.S02 := :Old.S02;
    v_R.R_Old.S03 := :Old.S03;
    v_R.R_Old.S04 := :Old.S04;
    v_R.R_Old.D01 := :Old.D01;
    v_R.R_Old.D02 := :Old.D02;
    v_R.R_Old.D03 := :Old.D03;
    v_R.R_Old.D04 := :Old.D04;
    v_R.R_Old.N01 := :Old.N01;
    v_R.R_Old.N02 := :Old.N02;
    v_R.R_Old.N03 := :Old.N03;
    v_R.R_Old.N04 := :Old.N04;

    -- Запись после изменения
    v_R.R_New.ID := :New.ID;
    v_R.R_New.S01 := :New.S01;
    v_R.R_New.S02 := :New.S02;
    v_R.R_New.S03 := :New.S03;
    v_R.R_New.S04 := :New.S04;
    v_R.R_New.D01 := :New.D01;
    v_R.R_New.D02 := :New.D02;
    v_R.R_New.D03 := :New.D03;
    v_R.R_New.D04 := :New.D04;
    v_R.R_New.N01 := :New.N01;
    v_R.R_New.N02 := :New.N02;
    v_R.R_New.N03 := :New.N03;
    v_R.R_New.N04 := :New.N04;
    
    -- Сохраним строку в коллекцию
    v_T(v_Index) := v_R;

  end after each row;
  
  after statement
  is
  begin

    -- Собственно, тут и должна быть обработка изменений оператора
    -- Для примера просто напечатаем массив изменений
    
    DBMS_OutPut.Put_Line('---------------');
    DBMS_OutPut.Put_Line('after statement');
    DBMS_OutPut.Put_Line('---------------');
    DBMS_OutPut.Put_Line('');

    -- Прочитаем результат
    for i in nvl(v_T.First, 0) .. nvl(v_T.Last, -1) loop

      v_R := v_T(i);
      
      -- Чисто для примера просто напечатаем массив изменений, ничего с ним не делая
      DBMS_OutPut.Put_Line('i = '||i);
      DBMS_OutPut.Put_Line('Operation = '||v_R.Operation);
      DBMS_OutPut.Put_Line('Old.ID = '||v_R.R_Old.ID);
      DBMS_OutPut.Put_Line('Old.S01 = '||v_R.R_Old.S01);
      DBMS_OutPut.Put_Line('Old.S02 = '||v_R.R_Old.S02);
      DBMS_OutPut.Put_Line('Old.S03 = '||v_R.R_Old.S03);
      DBMS_OutPut.Put_Line('Old.S04 = '||v_R.R_Old.S04);
      DBMS_OutPut.Put_Line('Old.D01 = '||v_R.R_Old.D01);
      DBMS_OutPut.Put_Line('Old.D02 = '||v_R.R_Old.D02);
      DBMS_OutPut.Put_Line('Old.D03 = '||v_R.R_Old.D03);
      DBMS_OutPut.Put_Line('Old.D04 = '||v_R.R_Old.D04);
      DBMS_OutPut.Put_Line('Old.N01 = '||v_R.R_Old.N01);
      DBMS_OutPut.Put_Line('Old.N02 = '||v_R.R_Old.N02);
      DBMS_OutPut.Put_Line('Old.N03 = '||v_R.R_Old.N03);
      DBMS_OutPut.Put_Line('Old.N04 = '||v_R.R_Old.N04);
      DBMS_OutPut.Put_Line('New.ID = '||v_R.R_New.ID);
      DBMS_OutPut.Put_Line('New.S01 = '||v_R.R_New.S01);
      DBMS_OutPut.Put_Line('New.S02 = '||v_R.R_New.S02);
      DBMS_OutPut.Put_Line('New.S03 = '||v_R.R_New.S03);
      DBMS_OutPut.Put_Line('New.S04 = '||v_R.R_New.S04);
      DBMS_OutPut.Put_Line('New.D01 = '||v_R.R_New.D01);
      DBMS_OutPut.Put_Line('New.D02 = '||v_R.R_New.D02);
      DBMS_OutPut.Put_Line('New.D03 = '||v_R.R_New.D03);
      DBMS_OutPut.Put_Line('New.D04 = '||v_R.R_New.D04);
      DBMS_OutPut.Put_Line('New.N01 = '||v_R.R_New.N01);
      DBMS_OutPut.Put_Line('New.N02 = '||v_R.R_New.N02);
      DBMS_OutPut.Put_Line('New.N03 = '||v_R.R_New.N03);
      DBMS_OutPut.Put_Line('New.N04 = '||v_R.R_New.N04);
      DBMS_OutPut.Put_Line('------------------------------------------');
      DBMS_OutPut.Put_Line('');

    end loop;

  end after statement;

end Trg$Cmp$ANB_Compound_Trg_Test_Table;
/

-- Инициация теста
truncate table ANB_Compound_Trg_Test_Table
/
-- Все одной пачкой для наглядности
declare
begin

  -- Вставка новых записей

  -- Первый инсерт
  insert
  into ANB_Compound_Trg_Test_Table
  (
    id
   ,S01
   ,S02
   ,S03
   ,S04
   ,D01
   ,D02
   ,D03
   ,D04
   ,N01
   ,N02
   ,N03
   ,N04
  )
  select
    rownum id
   ,rownum * 1 S01
   ,rownum * 2 S02
   ,rownum * 3 S03
   ,rownum * 4 S04
   ,date'2020-01-01' + rownum + 10 D01
   ,date'2020-01-01' + rownum + 20 D02
   ,date'2020-01-01' + rownum + 30 D03
   ,date'2020-01-01' + rownum + 40 D04
   ,rownum * 10 N01
   ,rownum * 20 N02
   ,rownum * 30 N03
   ,rownum * 40 N04
  from
    dual
  connect by
    level <= 10;

  -- Второй инсерт
  insert
  into ANB_Compound_Trg_Test_Table
  (
    id
   ,S01
   ,S02
   ,S03
   ,S04
   ,D01
   ,D02
   ,D03
   ,D04
   ,N01
   ,N02
   ,N03
   ,N04
  )
  select
    rownum + 20 id
   ,rownum * 1 S01
   ,rownum * 2 S02
   ,rownum * 3 S03
   ,rownum * 4 S04
   ,date'2020-01-01' + rownum + 10 D01
   ,date'2020-01-01' + rownum + 20 D02
   ,date'2020-01-01' + rownum + 30 D03
   ,date'2020-01-01' + rownum + 40 D04
   ,rownum * 10 N01
   ,rownum * 20 N02
   ,rownum * 30 N03
   ,rownum * 40 N04
  from
    dual
  connect by
    level <= 5;

  -- Update
  update
    ANB_Compound_Trg_Test_Table
  set
    N01 = id * 100
   ,N02 = id * 200
   ,N03 = id * 300
   ,N04 = id * 400
  where
    id <= 10;
    
  -- Удаление
  delete
  from
    ANB_Compound_Trg_Test_Table
  where
    id <= 3;

  -- Merge
  merge
  into
    ANB_Compound_Trg_Test_Table D
  using
  (
  select
    rownum id
   ,rownum * 1000 S01
   ,rownum * 2000 S02
   ,rownum * 3000 S03
   ,rownum * 4000 S04
   ,date'2020-01-01' + rownum + 10 D01
   ,date'2020-01-01' + rownum + 20 D02
   ,date'2020-01-01' + rownum + 30 D03
   ,date'2020-01-01' + rownum + 40 D04
   ,rownum * 10 N01
   ,rownum * 20 N02
   ,rownum * 30 N03
   ,rownum * 40 N04
  from
    dual
  connect by
    level <= 5
  ) S
  on
  (
    D.ID = S.ID
  )
  when matched then
  update
  set
    D.S01 = S.S01
   ,D.S02 = S.S02
   ,D.S03 = S.S03
   ,D.S04 = S.S04
  when not matched then
  insert
  (
    D.id
   ,D.S01
   ,D.S02
   ,D.S03
   ,D.S04
   ,D.D01
   ,D.D02
   ,D.D03
   ,D.D04
   ,D.N01
   ,D.N02
   ,D.N03
   ,D.N04
  )
  values
  (
    S.id
   ,S.S01
   ,S.S02
   ,S.S03
   ,S.S04
   ,S.D01
   ,S.D02
   ,S.D03
   ,S.D04
   ,S.N01
   ,S.N02
   ,S.N03
   ,S.N04
  );

  commit;
end;
/