declare
     type index_by_collection is table of varchar2(250) index by varchar2(50);
     function index_by_collection_constructor(
          p_indexes sys.odcivarchar2list := sys.odcivarchar2list(),
          p_values sys.odcivarchar2list := sys.odcivarchar2list())
          return index_by_collection
     is
          l_this index_by_collection;
     begin
          for i in 1..least(p_indexes.count, p_values.count) loop
                l_this(p_indexes(i)) := p_values(i);
          end loop;
          return l_this;
     end index_by_collection_constructor;
     function udf_with_default_parameter(
          p_param index_by_collection := index_by_collection_constructor())
          return pls_integer
     is
          i varchar2(2000);
          n pls_integer := 0;
     begin
          i := p_param.first;
          while i is not null loop
                n := n + 1;
                dbms_output.put_line('p_param(' || i || ')=' || p_param(i));
                i := p_param.next(i);
          end loop;
          return n;
     end udf_with_default_parameter;
begin
     dbms_output.put_line('return value of call with non-default parameter is: ' ||
          udf_with_default_parameter(
                index_by_collection_constructor(
                     sys.odcivarchar2list('a','b','c'),
                     sys.odcivarchar2list('1','2','3')
                )
          )
     );
     dbms_output.put_line('return value of call with default parameter is: "' || udf_with_default_parameter() || '"');
end;