create or replace
  function next_workday(
                        p_offset number,
                        p_date   date := trunc(sysdate)
                       )                      
    return date
    is
        v_res_date date;
    begin
        with not_a_holiday as (
                                select  p_date + level - 1 dt
                                  from  dual
                                  connect by p_date + level - 1 <= add_months(p_date,12) -- измени если нужно больше чем на год вперед.
                               minus
                                select  *
                                  from  holiday
                              ),
                  workdays as (
                               select  row_number() over(order by dt) rn,
                                       dt workday
                                 from  not_a_holiday
                                 where dt - trunc(dt,'iw') <= 4
                              )
        select  workday
          into  v_res_date
          from  workdays
          where connect_by_isleaf = 1
          start with workday = p_date - least(0,p_date - trunc(p_date + 2,'iw'))
          connect by rn = prior rn + 1
                 and level <= p_offset + 1;
        return v_res_date;
end;
/
with test_dates as (
                    select  date '2019-11-30' + level curr_date
                      from  dual
                      connect by level <= 13
                   )
select  to_char(curr_date,'mm/dd/yyyy, fmDay') current_date,
        to_char(next_workday(10,curr_date),'mm/dd/yyyy, fmDay') current_date_plus_10_workdays
  from  test_dates
  order by curr_date
/

CURRENT_DATE          CURRENT_DATE_PLUS_10_WORKDAYS
--------------------- ------------------------------
12/01/2019, Sunday    12/16/2019, Monday
12/02/2019, Monday    12/16/2019, Monday
12/03/2019, Tuesday   12/17/2019, Tuesday
12/04/2019, Wednesday 12/18/2019, Wednesday
12/05/2019, Thursday  12/19/2019, Thursday
12/06/2019, Friday    12/20/2019, Friday
12/07/2019, Saturday  12/23/2019, Monday
12/08/2019, Sunday    12/23/2019, Monday
12/09/2019, Monday    12/23/2019, Monday
12/10/2019, Tuesday   12/24/2019, Tuesday
12/11/2019, Wednesday 12/27/2019, Friday
12/12/2019, Thursday  12/30/2019, Monday
12/13/2019, Friday    12/31/2019, Tuesday

13 rows selected.

SQL>